Код VBA: диапазон Excel не вставляется для правильного отображения

Question

Ниже приведен мой код для вставки диапазона в Outlook для отправки электронной почты, но он не работает должным образом. Пожалуйста помоги.

Private Sub CommandButton1_Click()
'Created by Shenal Salgado
    Dim xOutApp As Object
    Dim xOutMail As Object
    Dim xMailBody As String
    Dim rng As Range
    On Error Resume Next
    Set xOutApp = CreateObject("Outlook.Application")
    Set xOutMail = xOutApp.CreateItem(0)
    Set rng = sh_main.Range("A1:E26")
    xMailBody = sh_main.Range("A1:E26")
                  On Error Resume Next
    With xOutMail
        .To = "xxxxxxxxxx"
        .Cc = ""
        .BCC = ""
        .Subject = "EOD SWAPTION CHECK: " & sh_main.Range("A1")
        .Body = xMailBody
        .Display
    End With
    On Error GoTo 0
    Set xOutMail = Nothing
    Set xOutApp = Nothing
End Sub

Answer 1

В большинстве случаев использование MailEnvelope действительно хорошо работает в Excel.

Потренируйтесь с этим кодом, запустите его и установите флажок отправлено в Outlook.

Sub EmAiLtoDave()
'Working in Excel 2002-2013
    Dim Sendrng As Range

    On Error GoTo StopMacro

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sendrng = Range("A1:E26")
    Sendrng.Select
    'Create the mail and send it
    With Sendrng

        ActiveWorkbook.EnvelopeVisible = True
        With .Parent.MailEnvelope

            ' Set the optional introduction field thats adds
            ' some header text to the email body.
            .Introduction = "Hi"

            With .Item
                .To = "SomeBody@Somewhere.com"
                .CC = ""
                .BCC = ""
                .Subject = "EOD SWAPTION CHECK: " & Range("A1")
                .Send
            End With

        End With
    End With

StopMacro:
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
    ActiveWorkbook.EnvelopeVisible = False

End Sub