Перетащите в Outlook сообщение в форму Windows - PullRequest
Новая
       10

Перетащите в Outlook сообщение в форму Windows

0 голосов
/ 07 сентября 2018

В настоящее время у меня есть приложение Windows Forms, которое принимает перетаскивание файлов из других приложений.Казалось, что все работало гладко, пока мы не обнаружили, что если мы добавили письмо, прикрепленное к письму, то все стало странным.

Например, у пользователей не возникло проблем с перетаскиванием вложенных файлов jpg или pdf непосредственно из электронных писем в приложение.,Но когда электронное письмо (MSG-файл) было прикреплено к электронному письму, и это было прикрепленное электронное письмо, которое пыталось добавить в программу, то вот что происходит: следующий код может правильно прочитать имя выбранного вложенияэто было перетащено в программу, но фактически скопированный файл является основным, содержащим электронную почту (включая все вложения).

Есть ли способ, которым я могу просто извлечь выбранное / перетаскиваемое сообщение?

Спасибо !!

Вот вся функция: 

Public Shared Function HandleFileDrops(ByVal e As System.Windows.Forms.DragEventArgs) As String
    ' Based on and Borrowed from http://allandynes.com/2015/10/vb-net-drag-and-drop-from-outlook/
    Try
        If e.Data.GetDataPresent(DataFormats.FileDrop) Then
            ' We have a file so lets pass it to the calling form
            Dim Filename As String() = CType(e.Data.GetData(DataFormats.FileDrop), String())
            HandleFileDrops = Filename(0)
        ElseIf e.Data.GetDataPresent("FileGroupDescriptor") Then
            ' We have a embedded file. First lets try to get the file name out of memory
            Dim theStream As IO.Stream = CType(e.Data.GetData("FileGroupDescriptor"), IO.Stream)
            Dim fileGroupDescriptor(512) As Byte
            theStream.Read(fileGroupDescriptor, 0, 512)
            Dim fileName As System.Text.StringBuilder = New System.Text.StringBuilder("")
            Dim i As Integer = 76

            While Not (fileGroupDescriptor(i) = 0)
                fileName.Append(Convert.ToChar(fileGroupDescriptor(i)))
                System.Math.Min(System.Threading.Interlocked.Increment(i), i - 1)
            End While

            theStream.Close()
            ' We should have the file name or if its an email, the subject line. Create our temp file based on the temp path and this info
            Dim myTempFile As String = IO.Path.GetTempPath & fileName.ToString
            ' Look to see if this is a email message. If so save that temporarily and get the temp file.
            If InStr(myTempFile, ".msg") > 0 Then
                Dim objOL As New Microsoft.Office.Interop.Outlook.Application
                Dim objMI As Microsoft.Office.Interop.Outlook.MailItem
                If objOL.ActiveExplorer.Selection.Count > 1 Then
                    MsgBox("You can only drag and drop one item at a time into this screen. Only the first item you selected will be used.", MsgBoxStyle.OkOnly Or MsgBoxStyle.Information, "One Item At A Time")
                End If
                For Each objMI In objOL.ActiveExplorer.Selection()
                    objMI.SaveAs(myTempFile)
                    Exit For
                Next
                objOL = Nothing
                objMI = Nothing
            Else
                ' If its a attachment we need to pull the file itself out of memory
                Dim ms As IO.MemoryStream = CType(e.Data.GetData("FileContents", True), IO.MemoryStream)
                Dim FileBytes(CInt(ms.Length)) As Byte
                ' read the raw data into our variable
                ms.Position = 0
                ms.Read(FileBytes, 0, CInt(ms.Length))
                ms.Close()
                ' save the raw data into our temp file
                Dim fs As IO.FileStream = New IO.FileStream(myTempFile, IO.FileMode.OpenOrCreate, IO.FileAccess.Write)
                fs.Write(FileBytes, 0, FileBytes.Length)
                fs.Close()
            End If
            ' Make sure we have a actual file and also if we do make sure we erase it when done
            If IO.File.Exists(myTempFile) Then
                ' Assign the file name to the add dialog
                HandleFileDrops = myTempFile
            Else
                HandleFileDrops = String.Empty
            End If
        Else
            Throw New System.Exception("An exception has occurred.")
        End If
    Catch ex As Exception
        MsgBox("Could not copy file from memory. Please save the file to your hard drive first and then retry your drag and drop.", MsgBoxStyle.OkOnly Or MsgBoxStyle.Information, "Drag and Drop Failed")
        HandleFileDrops = String.Empty
    End Try

End Function

В частности, этот раздел обрабатывает электронную почту: 

                Dim objOL As New Microsoft.Office.Interop.Outlook.Application
                Dim objMI As Microsoft.Office.Interop.Outlook.MailItem
                If objOL.ActiveExplorer.Selection.Count > 1 Then
                    MsgBox("You can only drag and drop one item at a time into this screen. Only the first item you selected will be used.", MsgBoxStyle.OkOnly Or MsgBoxStyle.Information, "One Item At A Time")
                End If
                For Each objMI In objOL.ActiveExplorer.Selection()
                    objMI.SaveAs(myTempFile)
                    Exit For
                Next
                objOL = Nothing
                objMI = Nothing

1 Ответ

0 голосов
/ 13 сентября 2018

После того, как я действительно посмотрел код, который я позаимствовал из других источников в сети, я теперь точно вижу, что он делает.Раздел кода, который сохраняет сообщения Outlook, создает новый экземпляр текущего объекта Outlook, а затем вызывает этот объект для извлечения его выбранных элементов, который будет являться основным выбранным электронным письмом, а не прикрепленным электронным письмом, которое было перетащено.Мне удалось добавить пару строк кода, чтобы сделать несколько сравнений либо по электронной почте, либо по имени вложения, чтобы увидеть, что к чему.

Теперь это хорошо работает для моих нужд: 

                Dim objOL As New Microsoft.Office.Interop.Outlook.Application
                Dim objMI As Microsoft.Office.Interop.Outlook.MailItem
                If objOL.ActiveExplorer.Selection.Count > 1 Then
                    MsgBox("You can only drag and drop one item at a time into this screen. Only the first item you selected will be used.", MsgBoxStyle.OkOnly Or MsgBoxStyle.Information, "One Item At A Time")
                End If

                'If the message itself has the same name as fileName, then just save the selected MailObject
                'Otherwise, iterate through all the attachments to the MailObject and save the one that hase that same name as the fileName
                For Each objMI In objOL.ActiveExplorer.Selection()
                    If objMI.Subject = fileName.ToString() Then
                        objMI.SaveAs(myTempFile)
                    Else 
                        Dim objAttach As Microsoft.Office.Interop.Outlook.Attachments = objMI.Attachments
                        For Each attach As Microsoft.Office.Interop.Outlook.Attachment In objAttach
                            If attach.FileName = fileName.ToString() Then
                                attach.SaveAsFile(myTempFile)
                            End If
                        Next
                    End If

                    Exit For
                Next
                objOL = Nothing
                objMI = Nothing
...