VBA Outlook Подпись

Question

Я попытался вставить разные коды, чтобы подпись по умолчанию в Outlook отображалась в конце этой строки кода при создании электронного письма. Есть предложения?

Private Sub CommandButton1_Click()
    Dim xOutApp As Object
    Dim xOutMail As Object
    Dim xMailBody As String
    Dim signature As String
    On Error Resume Next
    Set xOutApp = CreateObject("Outlook.Application")
    Set xOutMail = xOutApp.CreateItem(0)
    xMailBody = "Hello," & vbCrLf & vbCrLf & "I recently reviewed a call of yours and the information that we reviewed in our coaching session is as follows:" & vbCrLf & vbCrLf & _
              "Call Duration: " & Sheets("Sheet1 (13)").Range("j38").Value & vbCrLf & _
              "Date: " & Sheets("Sheet1 (13)").Range("j39").Value & vbCrLf & _
              "Coaching Feedback: " & Sheets("Sheet1 (13)").Range("J40").Value & vbCrLf & signature
                  On Error Resume Next
    With xOutMail
        .To = Range("D39")
        .CC = Range("G39")
        .BCC = ""
        .Subject = "Quality Audit Coaching"
        .Body = xMailBody
        .Display
    End With
    On Error GoTo 0
    Set xOutMail = Nothing
    Set xOutApp = Nothing
End Sub

Answer 1

Я вижу, у вас есть переменная сигнатуры Dim, но я не вижу, чтобы вы присваивали какой-либо объект.

Попробуйте выполнить следующее, если это не тело HTML

With xOutMail
    .To = Range("D39")
    .CC = Range("G39")
    .BCC = ""
    .Subject = "Quality Audit Coaching"
    .Display
    .Body = xMailBody & .Body
   ' .Send
End With

И если его HTML-тело, то измените его на .HTMLBody = xMailBody & .HTMLBody

Или вы можете установить Dim signature variable

Пример

Set xOutApp = CreateObject("Outlook.Application")
Set xOutMail = xOutApp.CreateItem(0)

With xOutMail
    .Display
     signature = .HTMLBody
End With

Свойство MSDN HTMLBody

Возвращает или задает строку, представляющую тело HTML указанного элемента.Свойство HTMLBody должно быть строкой синтаксиса HTML.Чтение / запись.

MSDN. Свойство тела

Возвращает или задает строку, представляющуютекст открытого текста элемента Outlook.Чтение / запись.