Как удалить текст, вставленный после закладки, чтобы я мог вставить новый текст

Question

Я настроил несколько закладок, и когда нажата кнопка, запускается макрос для вставки дат в закладки. Это прекрасно работает. если я снова нажму кнопку, новые даты будут вставлены перед существующими датами.

Я хочу знать, какой код использовать для удаления старых дат и добавления новых дат.

Я нашел код, который перечисляет все мои закладки.

Dim d As Document
'Set d = Documents.Add("G:\My Drive\Moss\CRM\Work in progress\action plan 
\Wordchange.docm")
Set d = ActiveDocument

Dim b As Bookmark

Dim dt As Date
'dt = DateAdd("d", 21, DateTime.Now)
dt = DateAdd("d", 90, Date)
Set b = d.Bookmarks("weeksadd3m")
b.Range.Text = Format(dt, "dd/mm/yyyy")

Я хотел бы очистить текст после закладки, чтобы можно было вставлять свежие даты.

Спасибо всем, кто примет это во внимание.

мох

Answer 1

Закладка должна быть настроена так, чтобы охватить диапазон ее нового содержания. Попробуйте код так: -

Private Sub SetBookMark()

    Dim Doc As Document
    Dim Rng As Range
    Dim Mark As String
    Dim Dt As Date

    'Set Doc = Documents.Add("G:\My Drive\Moss\CRM\Work in progress\" & _
                             "action plan\Wordchange.docm")
    Set Doc = ActiveDocument
    Mark = "weeksadd3m"
    Dt = DateAdd("m", 3, Date)

    With Doc.Bookmarks
        If .Exists(Mark) Then
            Set Rng = .Item(Mark).Range
            Rng.Text = Format(Dt, "dd/mm/yyyy")
            .Add Mark, Rng
        End If
    End With
End Sub