Как импортировать данные из CSV-файла в XLSM

Question

В настоящее время пытаюсь импортировать данные из файла CSV с помощью командной кнопки. Когда я запускаю кнопку, я не получаю никаких ошибок, однако ничего не распечатывается.

Private Sub CommandButton23_Click()
Dim Next_Row As Long
    Next_Row = 1

File = Application.GetOpenFilename _
        ("CSV Files (*.csv), *.csv", , "Select the CSV file", , False)

    If File = False Then
        MsgBox_Response = MsgBox("File could not be opened or is not compatible", vbOKOnly)
        Else
        Open File For Input As #1

        row_number = 1
      Do Until EOF(1)

            Line Input #1, LineFromFile

            LineItems = Split(LineFromFile, ",")
          Loop
          End If

        row_number = row_number + 1
        Debug.Print LineFromFile
    Close #1

End Sub

Я хочу, чтобы все данные из CSV-файла распечатывались на другом листе, где у меня настроены макросы.

Answer 1

Я думаю, вы просто неправильно указали свой код

Dim File As Variant
Dim MsgBox_Response As Long
Dim LineFromFile As String
Dim LineItems As Variant
Dim RowCounter As Long

File = Application.GetOpenFilename _
("CSV Files (*.csv), *.csv", , "Select the CSV file", , False)

If File = False Then
    MsgBox_Response = MsgBox("File could not be opened or is not compatible", vbOKOnly)
Else
    Open File For Input As #1

    ' Update this with your sheet reference
    With Sheet1
        Do Until EOF(1)
            Line Input #1, LineFromFile

            LineItems = Split(LineFromFile, ",")
            ' Increment row counter
            RowCounter = RowCounter + 1
            .Range("A" & RowCounter).Resize(, UBound(LineItems) + IIf(LBound(LineItems) = 0, 1, 0)).Value2 = LineItems
            Debug.Print Join(LineItems, vbTab)
        Loop
    End With
    Close #1
End If