Как мне объединить монады в Хаскеле? - PullRequest
Новая
       64

Как мне объединить монады в Хаскеле?

18 голосов
/ 14 июля 2009

В частности, мне нужно иметь возможность комбинировать монаду CGI с монадой IO, но пример того, как объединить монаду IO с монадой Maybe, может быть даже лучше ...

Ответы [ 3 ]

21 голосов
/ 15 июля 2009

Я предполагаю, что вы хотите использовать монаду Maybe для досрочного завершения (например, break или return в C).

В этом случае вы должны использовать MaybeT из пакета MaybeT (cabal install MaybeT). 

main = do
  runMaybeT . forever $ do
    liftIO $ putStrLn "I won't stop until you type pretty please"
    line <- liftIO getLine
    when ("pretty please" == line) mzero
  return ()

MaybeT является версией монады возможно для преобразования монады.

Трансформаторы монад "добавляют функциональность" к другим монадам.

17 голосов
/ 14 июля 2009

Вы точно не говорите, как вы хотите объединить IO и Maybe, но я предполагаю, что у вас есть много функций, которые возвращают IO (Maybe a), которые вы хотите легко объединить. В основном вы хотите рассматривать IO (Maybe a) как отдельный тип со своим собственным Monad экземпляром: 

newtype IOMaybe a = IOM (IO (Maybe a))

-- "unpack" a value of the new type
runIOMaybe :: IOMaybe a -> IO (Maybe a)
runIOMaybe (IOM a) = a

instance Monad IOMaybe where
   -- bind operator
   (IOM ioa) >>= f = IOM $ do
      a <- ioa
      case a of
         Nothing -> return Nothing
         Just v  -> runIOMaybe (f v)

   -- return
   return a = IOM (return (Just a))

-- maybe also some convenience functions
returnIO :: IO a -> IOMaybe a
returnIO ioa = IOM $ do
   v <- ioa
   return (Just v)

returnMaybe :: Maybe a -> IOMaybe a
returnMaybe ma = IOM (return ma)

При этом вы можете использовать do -Notation для объединения функций, которые возвращают IO (Maybe a), IO a или Maybe a: 

f1 :: Int -> IO (Maybe Int)
f1 0 = return Nothing
f1 a = return (Just a)

main = runIOMaybe $ do
   returnIO $ putStrLn "Hello"
   a <- returnMaybe $ Just 2
   IOM $ f1 a
   return ()

Обычно то, что объединяет и модифицирует монады, как это, называется преобразователь монад , и GHC поставляется с пакетом , который включает в себя преобразователи монад для общих случаев. Если в этой библиотеке монадных преобразователей есть что-то, что подходит для вашего сценария, зависит от того, как именно вы хотите объединить Maybe и IO.

0 голосов
/ 14 июля 2009

В каком смысле вы хотите объединить монады? 

f :: Int -> IO (Maybe Int)
f x = do
    putStrLn "Hello world!"
    return $ if x == 0 then Nothing else Just x

Может быть оценено как: 

[1 of 1] Compiling Main             ( maybe-io.hs, interpreted )
Ok, modules loaded: Main.
*Main> f 0
Hello world!
Nothing
*Main> f 3
Hello world!
Just 3
...