QML Treeview: как получить QModelIndex для детей - PullRequest
Новая
       39

QML Treeview: как получить QModelIndex для детей

0 голосов
/ 10 сентября 2018

У меня есть QML TreeView с QStandardItemModel и я использую ItemSelectionModel для управления выбором. ItemSelectionModel хочет QModelIndex для своей функции select. Как я могу получить QModelIndex детей на мой взгляд?

Дерево выглядит так:

  • файл 1
    • задание 1
    • задание 2
  • файл 2
    • задание 1

Я хочу выбрать task2, когда я нажимаю на него (у меня может быть MouseArea в делегате) (чтобы TreeView выделил его), и для этого я должен вызвать ItemSelectionModel.select с QModelIndex задачи 2. Но я не не знаю, как я могу получить QModelIndex для task2.

QStandardItemModel является производным от QAbstractItemModel и, следовательно, предоставляет функцию индекса: 

 virtual QModelIndex    index(int row, int column, const QModelIndex & parent = QModelIndex()) const

но для использования этой функции мне нужно знать индекс родителя. Как я могу получить это из вида?

1 Ответ

0 голосов
/ 10 сентября 2018

Чтобы получить ребенка, вы должны сначала иметь родителя, поэтому в случае вашей схемы вы должны получить "file1" , и для этого вы должны получить его родителя, а этот родитель - rootIndex из TreeView, поэтому последовательность: rootIndex -> file1 -> task1.

main.cpp 

#include <QGuiApplication>
#include <QQmlApplicationEngine>
#include <QQmlContext>
#include <QStandardItemModel>

int main(int argc, char *argv[])
{
    QCoreApplication::setAttribute(Qt::AA_EnableHighDpiScaling);

    QGuiApplication app(argc, argv);

    QStandardItemModel model;

    QStandardItem *item1 = new QStandardItem("file1");
    item1->appendRows({new QStandardItem("task1"), new QStandardItem("task2")});

    QStandardItem *item2 = new QStandardItem("file2");
    item2->appendRows({new QStandardItem("task1")});

    model.appendRow(item1);
    model.appendRow(item2);

    QQmlApplicationEngine engine;
    engine.rootContext()->setContextProperty("tree_model", &model);
    engine.load(QUrl(QStringLiteral("qrc:/main.qml")));
    if (engine.rootObjects().isEmpty())
        return -1;

    return app.exec();
}

main.qml 

import QtQuick 2.9
import QtQuick.Window 2.2
import QtQuick.Controls 1.4
import QtQml.Models 2.11

Window {
    visible: true
    width: 640
    height: 480
    TreeView {
        id: treeView
        anchors.fill: parent
        model: tree_model
        selectionMode: SelectionMode.MultiSelection
        selection: ItemSelectionModel {
            id: ism
            model: tree_model
        }
        TableViewColumn {
            title: "Name"
            role: "display"
            width: 300
        }
        Component.onCompleted: {
            expandAll()

            var ix1 = tree_model.index(0, 0, treeView.rootIndex)
            var ix = tree_model.index(0, 0, ix1)
            ism.select(ix, ItemSelectionModel.Select)
        }
    }

    // https://forum.qt.io/topic/75395/qml-treeview-expand-method-not-working
    function expandAll() {
        for(var i=0; i < tree_model.rowCount(); i++) {
            var index = tree_model.index(i,0)
            if(!treeView.isExpanded(index)) {
                treeView.expand(index)
            }
        }
    }
}

enter image description here

Обновление:

Чтобы получить индекс нажатого элемента, вы должны использовать styleData.index: 

import QtQuick 2.9
import QtQuick.Window 2.2
import QtQuick.Controls 1.4
import QtQml.Models 2.11

Window {
    visible: true
    width: 640
    height: 480
    TreeView {
        id: treeView
        anchors.fill: parent
        model: tree_model
        selectionMode: SelectionMode.MultiSelection
        selection: ItemSelectionModel {
            id: ism
            model: tree_model
        }
        TableViewColumn {
            title: "Name"
            role: "display"
            width: 300
        }
        itemDelegate: Item {
            Text {
                anchors.verticalCenter: parent.verticalCenter
                color: styleData.textColor
                elide: styleData.elideMode
                text: styleData.value

            }
            MouseArea{
                anchors.fill: parent
                onClicked: {
                    var ix = tree_model.index(0, 0, styleData.index)
                    ism.select(ix, ItemSelectionModel.Select)
                }
            }
        }
    }
}
...