Динамически выполнять запрос в хранимой процедуре в Oracle

Question

Выберите все таблицы базы данных, где столбцы совпадают, чем передают имя таблицы в следующий запрос, используя цикл. Если имя столбца и значения столбца совпадают, то возвращают true и существуют для цикла с использованием хранимой процедуры:

CREATE OR REPLACE PROCEDURE TEST 
(
NAME IN VARCHAR2 ,
ID IN NUMBER,
RE OUT SYS_REFCURSOR 
) AS

BEGIN
OPEN  RE FOR SELECT A.TABLE_NAME FROM
user_tables A JOIN user_tab_columns C
ON C.TABLE_NAME = A.TABLE_NAME
WHERE C.COLUMN_NAME = NAME;

FOR RE IN LOOP

v_Sql := 'SELECT COUNT(*) FROM '|| LOOP.TABLE_NAME || 'WHERE COLUMN_NAME = 
ID';
EXECUTE IMMEDIATE v_Sql
IF v_Sql%ROWCOUNT > 0 THEN
return true; 
EXIT

END LOOP;

END TEST;

Для лучшего понимания проблемы

//Get all the tables of database where campus_id is exist in any table of 
 database
 Campus, Class, Section (3 tables found)
 Apply forloop on the records
 Select count(campus_id) as total from (table name using loop) where campus_id = 1(value 
 pass)
 if(total > 0){

 Exist for loop and return true
 }
 else{
 Again iterate the loop to next value
 } 

Answer 1

То, что вы описали, не имеет особого смысла. Если есть несколько таблиц, которые содержат проверяемый столбец, и вы выходите из цикла, как только найдете первую, как насчет остальных?

Вот что я сделаю, посмотрим, поможет ли это. Я создам функцию (не процедуру), которая возвращает таблицу . Для этого я сначала создам тип (ы):

SQL> create or replace type t_record as object (tn varchar2(30), cnt number);
  2  /

Type created.

SQL> create or replace type t_table as table of t_record;
  2  /

Type created.

SQL>

Функция:

• в курсоре FOR цикл Я выбираю таблицы, содержащие этот столбец
• L_STR используется для составления оператора SELECT
• DBMS_OUTPUT.PUT_LINE используется, чтобы сначала отобразить его, чтобы я мог визуально проверить, правильно ли он установлен или нет.
• если это так, я запускаю его с EXECUTE IMMEDIATE
• результат сохраняется в виде таблицы и возвращается вызывающей стороне

---

SQL> create or replace function f_colname
  2    (par_column_name  in varchar2,
  3     par_column_value in varchar2
  4    )
  5    return t_table
  6  is
  7    retval t_table := t_table();
  8    l_str  varchar2(200);
  9    l_cnt  number;
 10  begin
 11    for cur_r in (select table_name
 12                  from user_tab_columns
 13                  where column_name = par_column_name
 14                 )
 15    loop
 16      l_str := 'select count(*) from ' || cur_r.table_name ||
 17               ' where ' || par_column_name || ' = ' ||
 18               chr(39) || par_column_value || chr(39);
 19      -- Display l_str first, to make sure that it is OK:
 20      -- dbms_output.put_line(l_str);
 21      execute immediate l_str into l_cnt;
 22      retval.extend;
 23      retval(retval.count) := t_record(cur_r.table_name, l_cnt);
 24    end loop;
 25    return retval;
 26  end;
 27  /

Function created.

Тестирование:

SQL> select * from table (f_colname('DEPTNO', '10'));

TN                                    CNT
------------------------------ ----------
TEST_201812                             1
DEPT                                    1
EMP                                     3

SQL> select * from table (f_colname('ENAME', 'KING'));

TN                                    CNT
------------------------------ ----------
EMP                                     1
BONUS                                   1

SQL>

Это не будет работать должным образом для некоторых типов данных (например, DATE) и должно быть откорректировано, если необходимо.

---

[РЕДАКТИРОВАТЬ: после того, как вы отредактировали вопрос]

Хорошо, тогда это еще проще. Это все еще должна быть функция (которая возвращает логическое значение, поскольку вы сказали, что - в случае, если что-то найдено - вы хотите вернуть TRUE). Код во многом похож на предыдущую функцию.

SQL> create or replace function f_colname
  2    (par_column_name  in varchar2,
  3     par_column_value in varchar2
  4    )
  5    return boolean
  6  is
  7    l_str  varchar2(200);
  8    l_cnt  number;
  9    retval boolean := false;
 10  begin
 11    for cur_r in (select table_name
 12                  from user_tab_columns
 13                  where column_name = par_column_name
 14                 )
 15    loop
 16      l_str := 'select count(*) from ' || cur_r.table_name ||
 17               ' where ' || par_column_name || ' = ' ||
 18               chr(39) || par_column_value || chr(39);
 19      -- Display l_str first, to make sure that it is OK:
 20      -- dbms_output.put_line(l_str);
 21      execute immediate l_str into l_cnt;
 22      if l_cnt > 0 then
 23         retval := true;
 24         exit;
 25      end if;
 26    end loop;
 27    return retval;
 28  end;
 29  /

Function created.

Тестирование: поскольку вы не можете вернуть Boolean на уровне SQL, вам необходимо использовать анонимный блок PL / SQL, как показано ниже:

SQL> declare
  2    l_ret boolean;
  3  begin
  4    if f_colname('DEPTNO', '15') then
  5       dbms_output.put_line('It exists');
  6    else
  7       dbms_output.put_line('It does not exist');
  8    end if;
  9  end;
 10  /
It does not exist

PL/SQL procedure successfully completed.

SQL>