Netlogo: опрос переменных других агентов - PullRequest
Новая
       4

Netlogo: опрос переменных других агентов

0 голосов
/ 10 сентября 2018

Я пытаюсь попросить агентов принять решение на основе того, находится ли переменная другого агента между личным минимальным и максимальным значениями первого агента.У меня проблемы с синтаксисом, ожидаемым netlogo.

Этот бит в полном коде ниже: 

to settle-decision
  ask turtles [
    ifelse ( myneighbor mycall ) > myminthresh AND myneighbor mycall < mymaxthresh)
      [ set settled? true ]
      [ set color yellow ]

В конце концов я хочу заставить агентов делать более интересные вещи, чем менять цвета, ноЯ не могу пройти мимо этого первым!Любая помощь наиболее ценится. 

turtles-own [
  myneighbor                                 ;; closest other male frog to myself
  mycall                                     ;; the amplitude (loudness) of my own call
  myminthresh                                ;; when my neighbor's call is below this threshold, I move toward him
  mymaxthresh                                ;; when my neighbor's call is above this threshold, I move away from him
  myNND                                      ;; the distance to my nearest neighbor
  settle?                                    ;; true if male decides to create a territory and stop moving

 ]


to setup

  clear-all
  create-turtles population [                         ;; use the population slider to choose number of males

set size 1.5                                      ;; easy to see but is it actual agent size or just agent image size?
setxy random-xcor random-ycor                     ;; distribute frogs randomly in the landscape

set mycall random 100                             ;; choose the amplitude of my own call from a random distribution 0 to 100
set color scale-color red mycall 0 100            ;; allows easy visualization of variability in call amplitude
                                                  ;; lighter color is a higher amplitude
set myminthresh inputminthresh                    ;; use the input on interface to set the min-threshold
set mymaxthresh inputmaxthresh                    ;; use the input on the interface to set the max-threshold
set myNND 0                                       ;; initialize nearest neighbor distance for all

  ]

  reset-ticks

end

to go
  choose-neighbors
  settle-decision
  move-turtles
  tick
end

to choose-neighbors
   ask turtles [
    set myneighbor min-one-of other turtles [distance myself]  ;; choose my nearest neighbor based on distance
    set myNND distance myneighbor

  ]
end


to settle-decision
  ask turtles [
    ifelse ( myneighbor mycall ) > myminthresh AND myneighbor mycall < mymaxthresh)
    [ set settled? true ]
    [ set color yellow ]
  ]
end

to move-turtles
  ask turtles [
    face myneighbor
    ifelse mycall < myminthresh
        [ set color blue ]
        [ set color yellow ]
                                                              ;; this works but everybody moves so needs more work
    fd 5
    pendown
  ]
end

1 Ответ

0 голосов
/ 10 сентября 2018

Необходимый вам примитив - of с кодом типа [variablename] of agent.Я не могу проверить это, но, вероятно, вместо: 

to settle-decision
  ask turtles [
    ifelse ( myneighbor mycall ) > myminthresh AND myneighbor mycall < mymaxthresh)
    [ set settled? true ]
    [ set color yellow ]
  ]
end

try 

to settle-decision
  ask turtles [
    ifelse ([mycall] of myneighbor > myminthresh) AND ([mycall] of myneighbor < mymaxthresh)
    [ set settled? true ]
    [ set color yellow ]
  ]
end
...