Пакетное программирование = Как сделать так, чтобы символы отображались медленно, когда я эхо, как если бы вы печатали их - PullRequest
Новая
       12

Пакетное программирование = Как сделать так, чтобы символы отображались медленно, когда я эхо, как если бы вы печатали их

0 голосов
/ 19 января 2019

Если вы когда-либо видели фильм о хакере, вы видели, как код медленно появляется символ за символом, как будто кто-то его печатает. Я хочу сделать это в пакетном режиме. Я нашел какой-то код, который делал похожую вещь, но с дырочными линиями.

Код можно найти по адресу: Как иметь несколько цветов в пакетном файле Windows? Ответ Дбенхэма.

Я пытался использовать disableDelayedExpansion, поскольку команда «звучала» так, как будто собиралась сделать то, что я хотела, но я ничего не получила

Спасибо за любую помощь заранее.

Кроме того, своего рода пример того, что я хочу сделать- текст появляется медленно gif

Ответы [ 2 ]

0 голосов
/ 19 января 2019

В зависимости от содержимого вашей строки, вам может подойти что-то простое. 

@Echo Off

Set "STRING=Try this, unfortunately it is untested!"

For /F %%A In ('"Prompt $H&For %%B In (1) Do Rem"') Do Set "BS=%%A"

For /F Delims^=^ EOL^= %%A In ('"(CMD/U/CEcho=%STRING%)|Find /V """'
) Do Set/P "=a%BS%%%A"<Nul & PathPing 127.0.0.1 -n -q 1 -p 100 1>Nul

Вы можете изменить скорость отображения букв, изменив число 100 при необходимости. Возможно, попробуйте 200 для медленного набора текста и 50 для более быстрого!

0 голосов
/ 19 января 2019

попробуйте это: 

@echo off
:typewriter
setlocal enableDelayedExpansion
set "string=%~1"
call ::strlen "%string%#" len
if "%~2" neq "" (
    set /a _timeout=%~2
) else (
    set _timeout=500
)

set "carret=^"
for /l %%a in (0,1,%len%) do (

    set "letter=!string:~%%a,1!"


    for /f %%# in (">" "<" "|" "&") do (
        if "!prev!" equ "%%#" do set "prev=^^%%#"
    )

    if "!letter!" equ " " (
        set "suffix=!suffix! "
    ) 


    ping 192.0.2.0 -n 1 -w %_timeout% 1>nul 2>&1
    if "!prev!" neq " " (
        break|set /p=!carret!!prev!!suffix!
        set "suffix="
    )
    set "prev=!letter!"
)

endlocal 
exit /b 0 %errorlevel%

:strlen
Setlocal EnableDelayedExpansion
:: strLen String [RtnVar]
::             -- String  The string to be measured, surround in quotes if it contains spaces.
::             -- RtnVar  An optional variable to be used to return the string length.
Set "s=#%~1"
Set "len=0"
For %%N in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
  if "!s:~%%N,1!" neq "" (
    set /a "len+=%%N"
    set "s=!s:~%%N!"
  )
)
Endlocal&if "%~2" neq "" (set %~2=%len%) else echo %len%
Exit /b

он принимает два аргумента - строку, которую вы хотите набирать медленно, и время ожидания в миллисекундах между каждой буквой.Пример (если вы называете это typewriter.bat): 

call typewriter.bat "hello world" 200

просто помните, что восклицательные знаки не будут напечатаны из-за задержки расширения. (но вы можете использовать специальные символы, такие как >, |, &, <)

Для дальнейшего ознакомления проверьте следующее: strlen , подстрока , сон в миллисекундах

...