Серво MQTT NodeMCU может реагировать только на полезную нагрузку десятичного массива - PullRequest
Новая
       57

Серво MQTT NodeMCU может реагировать только на полезную нагрузку десятичного массива

0 голосов
/ 20 января 2019

Я создаю кормушку для рыбы с сервоприводом SG90 и NodeMCU

Я использовал этот эскиз: 

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <Servo.h>
// Update these with values suitable for your network.
const char* ssid = "your_wifi_hotspot";
const char* password = "your_wifi_password";
 const char* mqtt_server = "broker.mqttdashboard.com";
//const char* mqtt_server = "iot.eclipse.org";

Servo myservo;  // create servo object to control a servo
WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
   delay(100);
  // We start by connecting to a WiFi network
    Serial.print("Connecting to ");
    Serial.println(ssid);
    WiFi.begin(ssid, password);
    while (WiFi.status() != WL_CONNECTED) 
    {
      delay(500);
      Serial.print(".");
    }
  randomSeed(micros());
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) 
{
  Serial.print("Command from MQTT broker is : [");
  Serial.print(topic);
  for(int i=0;i<length;i++)
  {
    if((int)payload[i]>194||(int)payload[i]<0)
    break;
    myservo.write((int)payload[i]);              // tell servo to go to position in variable '(int)payload[i]'
  }
}//end callback

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) 
  {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = "ESP8266Client-";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    //if you MQTT broker has clientID,username and password
    //please change following line to    if (client.connect(clientId,userName,passWord))
    if (client.connect(clientId.c_str()))
    {
      Serial.println("connected");
     //once connected to MQTT broker, subscribe command if any
      client.subscribe("OsoyooCommand");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 6 seconds before retrying
      delay(6000);
    }
  }
} //end reconnect()

void setup() {
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  myservo.attach(D1);  // attaches the servo on pin D1 to the servo object
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

}

Серво работает, когда я использую MQTTBox для отправки полезной нагрузки как«Десятичный массив», однако, мне тяжело, когда я посылаю полезную нагрузку в виде строки JSON.

Если я посылаю «Десятичный массив» 1, он превращает сервопривод в положение 1, однако, если я просто отправляю 1в качестве полезной нагрузки в виде строки он перемещает сервопривод в положение 49. Если я отправляю полезную нагрузку как 2, она перемещается в позицию 50. Если я отправляю полезную нагрузку как 10, то позиция 4948 выглядит как позиция 1 и позиция 0 одновременно.

Моя конечная цель - отправить эти полезные данные через HomeAssistant, которые отправляются в виде строки или JSON, однако на данный момент я не нашел правильного решения.Я был бы очень признателен за любую помощь или решение.

Ответы [ 2 ]

0 голосов
/ 21 января 2019

Полезные нагрузки MQTT имеют кодировку UTF-8, поэтому библиотека Arduino PubSubClient обрабатывает полезную нагрузку как массив uint8_t.

Если вы хотите отправлять и получать JSON, вы можете использовать ArduinoJson библиотека для анализа полезной нагрузки JSON.Таким образом, предполагая, что полезная нагрузка JSON выглядит следующим образом: 

{
  "position": 123
}

Затем вы можете реализовать обратный вызов, такой как: 

#include <ArduinoJson.h>

// Assuming a fixed sized JSON buffer
StaticJsonBuffer<200> jsonBuffer;

void callback(char* topic, byte* payload, unsigned int length) 
{
  JsonObject& root = jsonBuffer.parseObject(payload);

  if (root.success() && root.is<JsonObject>())
  {
    int position = root.as<JsonObject>().get<int>("position");

    myservo.write(position);
  }
}
0 голосов
/ 20 января 2019

Похоже, что двигатель занимает позицию ASCII-эквивалента числа, когда вы отправляете его в виде строки.

т.е.

  • ASCII-эквивалент символа '1'в 49 в десятичном виде
  • ASCII-эквивалент символа '2' в 50 в десятичном виде

Попробуйте отправить символ 'a', двигатель перейдет к 97.

Если вы хотите отправить строку, вам нужно изменить следующий код: 

for(int i=0;i<length;i++)
{
  if((int)payload[i]>194||(int)payload[i]<0)
    break;
  myservo.write((int)payload[i]);              // tell servo to go to position in variable '(int)payload[i]'
}

на: 

int location=String((char*)payload).toInt()
if((location>194)||(location<0))
  return;
myservo.write(location);
...