Научная нотация на схеме

Question

Я работаю над упражнениями SICP.

В Ex1.22 у меня есть вопрос о выполнении научной нотации в Схеме.

Это упражнение состоит в том, чтобы найти указанное число простых чисел, превышающее указанное значение.

; code to check whether a number is prime  
(define (smallest-divisor n)
  (find-divisor n 2))
(define (find-divisor n test-divisor)
  (cond ((> (square test-divisor) n) n)
        ((divides? test-divisor n) test-divisor)
        (else (find-divisor n (1+ test-divisor)))))
(define (divides? a b)
  (= (remainder b a) 0))
(define (prime? n)
  (= n (smallest-divisor n)))

; code to find prime numbers
; (search-for-primes 10 3) means find 3 prime numbers larger than 10
; the prime numbers and the time taken will be printed
(define (search-for-primes start count)
  (define (iter n c)
    (cond ((= c 0) (newline) (display "Done"))
          (else (iter (+ n 2) (- c (timed-prime-test n))))))
  (iter (if (even? start) (1+ start) start) 
        count))
(define (timed-prime-test n)
  (newline)
  (display n)
  (start-prime-test n (runtime)))
(define (start-prime-test n start-time)
  (cond ((prime? n)
         (report-prime (- (runtime) start-time))
         1)
        (else 0)))
(define (report-prime elapsed-time)
  (display " *** ")
  (display elapsed-time))

Мой вопрос заключается в разнице производительности ниже двух вызовов:

1 ]=> (search-for-primes 1000000000000 3)

1000000000039 *** 2.319999999999993
1000000000061 *** 2.3799999999999955
1000000000063 *** 2.3599999999999994

1 ]=> (search-for-primes 1e12 3)

1000000000039. *** 4.990000000000009
1000000000061. *** 4.960000000000008
1000000000063. *** 4.959999999999994

Очевидно, что научная запись занимает гораздо больше времени.Почему это происходит?

Мой код работает на последней версии MIT-Scheme:

MIT/GNU Scheme running under GNU/Linux
Type `^C' (control-C) followed by `H' to obtain information about interrupts.

Copyright (C) 2018 Massachusetts Institute of Technology
This is free software; see the source for copying conditions. There is NO warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

Image saved on Wednesday October 31, 2018 at 7:14:37 PM
  Release 10.1.2 || Microcode 15.3 || Runtime 15.7 || SF 4.41 || LIAR/i386 4.118

Answer 1

В то время как литерал 1000000000000 читается на схеме как точное целое число, 1e12 не понимается как точное и станет числом с плавающей запятой.Чтобы использовать научную запись для точных чисел, вы должны использовать префикс #e или inexact->exact:

(eqv? 1000000000000 1e12)                  ; ==> #f (not the same value)
(eqv? 1000000000000 #e1e12)                ; ==> #t (the same value)
(eqv? 1000000000000 (inexact->exact 1e12)) ; ==> #t (the same value)

Также, когда число не является целым числом, оно становится рациональным числом:

#e0.5 ; ==> 1/2

Для полноты вы можете сделать и обратное.Например.#i1000000000000 эквивалентен 1e12 и (exact->inexact 1000000000000).

ограничения

До R6RS не требовалось иметь полную числовую вышку.В отчете даже упоминается, что схема с только числами с плавающей запятой может быть полезной.Для R5RS и более ранних версий вам следует обратиться к документации по реализации, чтобы узнать, поддерживает ли она полную числовую вышку или нет.Схема MIT заявляет в своей документации, что они реализуют полную числовую башню.