Пользовательский отчет JUnit?

Question

Я использую задачи ant 'junit' и 'junitreport' для запуска моих тестов JUnit и создания отчета в конце (=> "Результаты модульного теста").

Есть ли какой-нибудь простой способ расширить этот вывод, чтобы получить больше информации, отображаемой в отчете? Например, добавить дополнительный столбец, содержащий ссылку на скриншот, сделанный тестом.

Я видел, что можно написать собственный тестовый модуль ant junit, такой как EclipseTestRunner но это довольно много усилий. Разве нет API для доступа к элементам отчета по единицам?

Answer 1

Задача junitreport использует XSLT для создания отчета из файлов XML, созданных задачей junit.

Вы можете настроить вывод, указав свой собственный XSLT, используя атрибут styledir вложенного элемента report:

<!-- use reportstyle/junit-frames.xsl to produce the report -->
<report styledir="reportstyle" format="frames" todir="testreport"/>

Для настройки вывода одним из вариантов будет сделать копию XSLT по умолчанию и изменить ее. Или вы можете найти альтернативный XSLT, который проще настроить для ваших целей.

Для небольших изменений может быть проще всего импортировать XSLT по умолчанию и переопределить любые шаблоны, которые вам нужно настроить. Например, чтобы добавить столбец для каждого теста, вам необходимо переопределить шаблон, который создает заголовок таблицы, и шаблон, который создает строку таблицы. Ниже я только что скопировал эти шаблоны и немного изменил их, чтобы добавить один столбец (ищите два дополнения, отмеченные <!-- ADDED -->).

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <!-- import the default stylesheet -->
  <xsl:import href="jar:file:lib/ant-junit.jar!/org/apache/tools/ant/taskdefs/optional/junit/xsl/junit-frames.xsl"/>

  <!-- override the template producing the test table header --> 
  <xsl:template name="testcase.test.header">
    <xsl:param name="show.class" select="''"/>
    <tr valign="top">
      <xsl:if test="boolean($show.class)">
        <th>Class</th>
      </xsl:if>
      <th>Name</th>
      <th>Status</th>
      <th width="80%">Type</th>
      <th nowrap="nowrap">Time(s)</th>

      <!-- ADDED -->
      <th>Screenshot</th>

    </tr>
  </xsl:template>

  <!-- override the template producing a test table row -->
  <xsl:template match="testcase" mode="print.test">
    <xsl:param name="show.class" select="''"/>
    <tr valign="top">
      <xsl:attribute name="class">
        <xsl:choose>
          <xsl:when test="error">Error</xsl:when>
          <xsl:when test="failure">Failure</xsl:when>
          <xsl:otherwise>TableRowColor</xsl:otherwise>
        </xsl:choose>
      </xsl:attribute>
      <xsl:variable name="class.href">
        <xsl:value-of select="concat(translate(../@package,'.','/'), '/', ../@id, '_', ../@name, '.html')"/>
      </xsl:variable>
      <xsl:if test="boolean($show.class)">
        <td><a href="{$class.href}"><xsl:value-of select="../@name"/></a></td>
      </xsl:if>
      <td>
        <a name="{@name}"/>
        <xsl:choose>
          <xsl:when test="boolean($show.class)">
            <a href="{concat($class.href, '#', @name)}"><xsl:value-of select="@name"/></a>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="@name"/>
          </xsl:otherwise>
        </xsl:choose>
      </td>
      <xsl:choose>
        <xsl:when test="failure">
          <td>Failure</td>
          <td><xsl:apply-templates select="failure"/></td>
        </xsl:when>
        <xsl:when test="error">
          <td>Error</td>
          <td><xsl:apply-templates select="error"/></td>
        </xsl:when>
        <xsl:otherwise>
          <td>Success</td>
          <td></td>
        </xsl:otherwise>
      </xsl:choose>
      <td>
        <xsl:call-template name="display-time">
          <xsl:with-param name="value" select="@time"/>
        </xsl:call-template>
      </td>

      <!-- ADDED -->
      <td>
        <a href="link/to/screenshot/for/test/{@name}">screenshot</a>
      </td>

    </tr>
  </xsl:template>

</xsl:stylesheet>

Вот как выглядит результат:

Answer 2

Awesome ans Jukka. Это продолжение ответа Юкки о том, как именно вы можете связать скриншот

  <!-- ADDED -->
  <td>
    <a href="link/to/screenshot/for/test/{@name}">screenshot</a>
  </td>

Вместо приведенного выше фрагмента в ответах Юкки, вот как вы можете связать скриншоты:

    <!-- Added screenshot link for failed tests -->
    <td>
        <xsl:variable name="class.name">
            <xsl:value-of select="translate(@classname,'.','/')"/>
        </xsl:variable>
        <xsl:variable name="junit.base">
            <xsl:call-template name="path"><xsl:with-param name="path" select="../@package"/></xsl:call-template>
        </xsl:variable>
    <xsl:choose>
        <xsl:when test="failure">
            <a href="{concat($junit.base,$class.name,'/',@name,'.png')}"><xsl:value-of select="@name"/></a>
        </xsl:when>
        <xsl:when test="error">
            <a href="{concat($junit.base,$class.name,'/',@name,'.png')}"><xsl:value-of select="@name"/></a>
        </xsl:when>
    </xsl:choose>
    </td>

Все, что вам нужно сделать после того, как будет сгенерирован отчет junit, - скопировать все скриншоты из каталога «selenium / screenshots /» прямо в каталог junit_report.

Приведенный выше код добавит ссылку только для неудачных тестов. Если вы хотите это для всех, измените код соответствующим образом.

Answer 3

Кроме того, если вы не хотите заменять основной xsl-файл, вы можете скопировать xsl-файл в корневую папку проекта, обновить его своими изменениями и, наконец, отредактировать файл build.xml, добавив атрибут styledir :

<report styledir="." format="noframes" todir="${junit.output.dir}"/>