XSLT IF правила оценки - PullRequest
Новая
       18

XSLT IF правила оценки

0 голосов
/ 14 мая 2018

Из XML-файла: 

    <store >
      <tools>
        <tool IDT="T1">
          <container>B1</container>
          <container>B2</container>
        </tool>
        <tool IDT="T2">
          <container>B1</container>
        </tool>
        <tool IDT="T3">
          <container>B2</container>
        </tool>
      </tools>
      <boxes>
        <box IDB="B1" height="10" width="20" length="30" weight="4"/>
        <box IDB="B2" height="5" width="40" length="30" weight="2"/>
      </boxes>
    </store>

Я пытаюсь отобразить для каждого блока список инструментов, которые входят в каждый блок.Для этого я написал следующий XSL: 

    <?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet version="2.0" 
                    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
                    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
                    xmlns:fn="http://www.w3.org/2005/xpath-functions">
      <xsl:output 
         method="html"
         encoding="UTF-8"
         doctype-public="-//W3C//DTD HTML 4.01//EN"
         doctype-system="http://www.w3.org/TR/html4/strict.dtd"
        indent="yes" />
      <xsl:template match="/">
      <html>
        <head>
          <title>Boxes contents</title>
          <link type="text/css" rel="stylesheet" href="styles.css" />
        </head>
        <body>
          <h1>Boxes contents</h1>
          <ul>
          <xsl:apply-templates select="/store/boxes/box" /> 
          </ul>
        </body>
      </html>
      </xsl:template>
      <xsl:template match="box" >
        <li><xsl:text>Box </xsl:text>
            <xsl:value-of select="@ID"/>
            <xsl:text>contains the following tools : </xsl:text>
        </li>
        <xsl:call-template name="findTools" >
          <xsl:with-param name="currentBOX"  select="@IDB"/>
        </xsl:call-template>
      </xsl:template>

      <xsl:template name="findTools" >
         <xsl:param name="currentBOX" />
         <xsl:for-each select="/store/tools/tool/container" >
            <xsl:if test="container = $currentBOX" >
               <br><xsl:value-of select="@IDT"/></br>
            </xsl:if>
         </xsl:for-each>
      </xsl:template>
    </xsl:stylesheet>

Когда я делаю это, я никогда не вижу инструменты.В отладке под OXYGEN я вижу, что IF никогда не соответствует действительности.Я не понимаю почему?Я запускаю в XPath и XSLT, спасибо за вашу помощь

1 Ответ

0 голосов
/ 14 мая 2018

Вы уже находитесь в элементе <container> внутри <xsl:for-each>. Детей нет, поэтому выбор еще <container> внутри <xsl:if> ничего не даст.

Вы хотите выполнить проверку с узла <tool>. 

<xsl:for-each select="/store/tools/tool">
    <xsl:if test="container = $currentBOX">
        <xsl:value-of select="@IDT"/><br />
    </xsl:if>
</xsl:for-each>

что проще записать как 

<xsl:for-each select="/store/tools/tool[container = $currentBOX]">
   <xsl:value-of select="@IDT"/><br />
</xsl:for-each>

В целом, более простой способ написания двух шаблонов был бы таков: 

<xsl:template match="box">
    <li>
        <xsl:text>Box </xsl:text>
        <xsl:value-of select="@ID"/>
        <xsl:text>contains the following tools : </xsl:text>
    </li>
    <xsl:apply-templates select="/store/tools/tool[container = current()/@IDB]" />
</xsl:template>

<xsl:template match="tool">
    <xsl:value-of select="@IDT"/><br />
</xsl:template>

И в качестве альтернативы вы можете использовать <xsl:key> для индексации <tool> элементов по их <container> значению: 

<xsl:key name="kToolByContainer" match="/store/tools/tool" use="container" />

<xsl:template match="box">
    <li>
        <xsl:text>Box </xsl:text>
        <xsl:value-of select="@ID"/>
        <xsl:text>contains the following tools : </xsl:text>
    </li>
    <xsl:apply-templates select="key('kToolByContainer', @IDB)" />
</xsl:template>

<xsl:template match="tool">
    <xsl:value-of select="@IDT"/><br />
</xsl:template>
...