Удалить элементы между двумя конкретными (HTML) тегами в XSLT 1.0? - PullRequest
Новая
       11

Удалить элементы между двумя конкретными (HTML) тегами в XSLT 1.0?

0 голосов
/ 23 января 2019

У меня есть источник ввода XML , как показано ниже: 

                        <p>(U) This product may contain copyrighted material.</p>
                        <h6>BODY</h6>
                        <p>Today, located in Don Chedi District, Suphan Buri Province.</p>
                        <h6>SOURCE DESCRIPTOR</h6>
                        <p>From the Royal Thai by the private company.</p>
                        <p>This product may contain copyrighted material</p>
                        <h6>PRODUCT DESCRIPTION</h6>
                        <p>The body of this product is a translation of original foreign-language material.</p>
                        <p>From the Royal News section</p>

Выход Требуется: 

                        <p>(U) This product may contain copyrighted material.</p>
                        <h6>BODY</h6>
                        <p>Today, located in Don Chedi District, Suphan Buri Province.</p>

                        <h6>PRODUCT DESCRIPTION</h6>
                        <p>The body of this product is a translation of original foreign-language material.</p>
                        <p>From the Royal News section</p>

Мне нужно удалить элемент <h6>, имеющий значение SOURCE DESCRIPTOR, и все последующие теги <p>. После <h6>SOURCE DESCRIPTOR</h6>

может быть более двух <p> тегов

Я пробовал что-то вроде 

<xsl:template match="p[following-sibling::*[self::h6='SOURCE DESCRIPTOR']]" />

Это дает противоположный результат, удаляя все <p>, за исключением требуемого.

Ответы [ 2 ]

0 голосов
/ 23 января 2019

Поскольку необходимо применить XSLT к данному входному источнику (который уже был результатом некоторого преобразования), я решил это, как показано ниже, что помогло выполнить данные требования: 

<xsl:template match="p['SOURCE DESCRIPTOR' = preceding-sibling::h6[1]]" mode="xhtml" xmlns="http://www.w3.org/1999/xhtml" />
<xsl:template match="h6[. = 'SOURCE DESCRIPTOR']" mode="xhtml" xmlns="http://www.w3.org/1999/xhtml" />
0 голосов
/ 23 января 2019

Учитывая правильно сформированный ввод, такой как:

XML 

<root>
    <p>(U) This product may contain copyrighted material.</p>
    <h6>BODY</h6>
    <p>Today, located in Don Chedi District, Suphan Buri Province.</p>
    <h6>SOURCE DESCRIPTOR</h6>
    <p>From the Royal Thai by the private company.</p>
    <p>This product may contain copyrighted material</p>
    <h6>PRODUCT DESCRIPTION</h6>
    <p>The body of this product is a translation of original foreign-language material.</p>
    <p>From the Royal News section</p>
</root>

следующая таблица стилей:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="p-by-h6" match="p" use="generate-id(preceding-sibling::h6[1])" />

<xsl:template match="/root">
    <xsl:copy>
        <xsl:copy-of select="key('p-by-h6', '')"/>
        <xsl:for-each select="h6[not(.='SOURCE DESCRIPTOR')]">
            <xsl:copy-of select="."/>
            <xsl:copy-of select="key('p-by-h6', generate-id())"/>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

вернет:

Результат 

<?xml version="1.0" encoding="UTF-8"?>
<root>
  <p>(U) This product may contain copyrighted material.</p>
  <h6>BODY</h6>
  <p>Today, located in Don Chedi District, Suphan Buri Province.</p>
  <h6>PRODUCT DESCRIPTION</h6>
  <p>The body of this product is a translation of original foreign-language material.</p>
  <p>From the Royal News section</p>
</root>
...