gawk: почему не «следующий»; подавить линии, соответствующие шаблону?

Question

У меня есть следующая программа на awk:

/.*needle.*/
{
    if ($0 != "hay needle hay")
    {
        print "yay: ", $1;
        next;
    }

    print "ya2";
    next;
}

{
    print "no";
    next;
}

Я запускаю его как gawk -f test.awk < some.log > out.log в GNU Awk 4.2.1, API: 2.0.

some.log:

hay hay hay
hay needle hay
needle
hay hay
hay
hay

out.log:

yay:  hay         
hay needle hay    
ya2               
needle            
yay:  needle      
yay:  hay         
yay:  hay         
yay:  hay         

Я ожидаю, что он напечатает только "ya2-new line-yay: needle".

Это вызывает вопросы:

• Почему действие шаблона вызывается даже на несовпадающих строках, а не безусловное действие? The purpose of the action is to tell awk what to do once a match for the pattern is found.
• Почему next; не подавляет печать соответствующей строки, так как print является только действием по умолчанию ? У нас есть действие не по умолчанию здесь. The next statement forces awk to immediately stop processing the current record and go on to the next record
• Я мог и сделал match() вызов внутри if() в действии по умолчанию, но почему этот вариант не сработал?

Answer 1

Вы, кажется, поклонник стиля отступа Allman .Я предполагаю, что блок if ($0 != ... должен выполняться только там, где запись соответствует needle - вам нужно поместить открывающую скобку в ту же строку, что и шаблон.

/.*needle.*/ {
    if ($0 != "hay needle hay")
    {
        print "yay: ", $1;
        next;
    }

    print "ya2";
    next;
}

Вывод:

no
ya2
yay:  needle
no
no
no

В awk символ новой строки - это терминатор, похожий на точку с запятой.

Теперь у вас есть:

# if the line matches "needle", print it verbatim
/.*needle.*/     

# And **also**, for every line, do this:
{
    if ($0 != "hay needle hay")
    {
        print "yay: ", $1;
        next;
    }

    print "ya2";
    next;
}