Добавить колонку даты vba

Question

Я ищу способ автоматического добавления столбца с текущей датой после того, как я вставил выбранные данные в лист. Мой текущий код VBA берет данные о торговле на конец дня, встраивается в тело письма и прикрепляет его в виде файла Excel перед отправкой в ​​соответствующие группы. Я хотел бы, чтобы VBA мог добавить столбец даты к активной рабочей таблице после запуска макроса. Код выглядит следующим образом:

Sub Mail_Sheet_Outlook_Body()

    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set rng = Nothing
    Set rng = ActiveSheet.UsedRange
    'You can also use a sheet name
    'Set rng = Sheets("YourSheet").UsedRange

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .to = "Nabil.Hure@dnb.no"
        .CC = ""
        .BCC = ""
        .Subject = "Today's Trades" & Date
        .HTMLBody = RangetoHTML(rng)
        .Attachments.Add ActiveWorkbook.FullName
        .Send                                    'or use .Display
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

Любой совет о том, как это сделать или куда поместить это в моем текущем коде VBA, будет полезен.

Answer 1

Поскольку вы держите UsedRange в переменной rng, вы можете добавить пару строк после Set rng = ActiveSheet.UsedRange:

Set rng = ActiveSheet.UsedRange
rng.Offset(, rng.Columns.Count).Resize(, 1) = Date
Set rng = rng.Resize(, rng.Columns.Count + 1)

Вторая строка устанавливает ссылку на столбец рядом сваш диапазон и заполняет его текущей датой.
Последняя строка добавляет новый столбец в переменную rng.Вы могли бы снова использовать UsedRange, но при тестировании я обнаружил, что это ненадежно - обычно лучше вообще не использовать UsedRange.

Чтобы найти последнюю ячейку без использования UsedRange, вы можете использовать FIND, чтобы найти последнюю непустую ячейку.

Sub Test()

    Dim rng As Range

    Set rng = ActiveSheet.Range("A1", LastCell(ActiveSheet))
    '...
    '...
    '...

End Sub

Public Function LastCell(wrkSht As Worksheet) As Range

    Dim lLastCol As Long, lLastRow As Long

    On Error Resume Next

    With wrkSht
        lLastCol = .Cells.Find("*", , , , xlByColumns, xlPrevious).Column
        lLastRow = .Cells.Find("*", , , , xlByRows, xlPrevious).Row


        If lLastCol = 0 Then lLastCol = 1
        If lLastRow = 0 Then lLastRow = 1

        Set LastCell = wrkSht.Cells(lLastRow, lLastCol)
    End With

    On Error GoTo 0

End Function

Answer 2

Если вы хотите добавить текущую дату / время к диапазону ячеек в активной рабочей таблице, вы можете использовать этот код:

ActiveSheet.Range(TopCornerCell, BottomCornerCell).Value = Now()

Только для даты (а не для времени) выможно использовать это:

ActiveSheet.Range(TopCornerCell, BottomCornerCell).Value = Int(Now())

Определение значений TopCornerCell и BottomCornerCell будет зависеть от ваших требований и данных.

Наконец, вы можете изменить форматирование диапазона с помощью Range.NumberFormat и ширина столбца с автоподгонкой Range.EntireColumn.Autofit