Ошибка значения для формата при использовании параметра data_format

Question

Я новичок и пытаюсь получить наш требуемый date_format. Я также пытался проверить другие форматы в date_format. Но я получаю эту ошибку.

Ошибка значения: данные времени '2018-11-16 11:18:58' не соответствуют формату '% m /% d /% Y% I:% M:% S% p'

Это генерируется следующим скриптом:

Комплект для тестирования роботов

    *** Settings ***
    Library  DateTime

    *** Variables ***
    ${UTC_OFFSET}  - 5 hours
    ${LOCAL_TIME_ZONE}  -05:00
    ${LOCAL_DATE_FORMAT}  %m/%d/%Y

    *** Test Cases ***
    Test title
        ${Supplied_Date}=  DateTime.Get Current Date  time_zone=UTC  increment=${UTC_OFFSET}  result_format=%Y-%m-%d %H:%M:%S
        Log  ${Supplied_Date}  console=true
        ${Supplied_Date}  DateTime.convert date  ${Supplied_Date}    result_format=%Y-%m-%d %H:%M:%S   exclude_millis=${True}   date_format=${LOCAL_DATE_FORMAT} %I:%M:%S %p
        Log  ${Supplied_Date}  console=true

Answer 1

Простое смешение значений result_format и date_format:

*** Settings ***
Library  DateTime

*** Variables ***
${UTC_OFFSET}  - 5 hours
${LOCAL_TIME_ZONE}  -05:00
${LOCAL_DATE_FORMAT}  %m/%d/%Y

*** Test Cases ***
Test title
    ${Supplied_Date}=  Get Current Date  
    ...    time_zone=UTC  
    ...    increment=${UTC_OFFSET}  
    ...    result_format=%Y-%m-%d %H:%M:%S
    Log  ${Supplied_Date}  console=true

    ${Supplied_Date}  Convert Date  
    ...    ${Supplied_Date}    
    ...    date_format=%Y-%m-%d %H:%M:%S   
    ...    exclude_millis=${True}   
    ...    result_format=${LOCAL_DATE_FORMAT} %I:%M:%S %p
    Log  ${Supplied_Date}  console=true