Невозможно просмотреть навигацию и ленту в БД MS Access - PullRequest
Новая
       6

Невозможно просмотреть навигацию и ленту в БД MS Access

0 голосов
/ 16 мая 2018

Я унаследовал проект MS Access и пытаюсь внести изменения в некоторые формы. Однако, когда я открываю файл в MS Access 2016, я не вижу меню навигации, верхней ленты или дизайна редактирования, чтобы внести какие-либо изменения. Я искал, что есть несколько способов обойти это, но также обнаружил, что каждый из них может быть запрещен разработчиком. Если каждый из них может быть запрещен, как другой разработчик может внести изменения?

Ниже я попробовал:

  • нажал F11, но ничего не появляется
  • Держите нажатой кнопку SHIFT, дважды щелкнув по файлу, но ничего не отображается
  • Нажмите CTRL + G, чтобы открыть VBE, но ничего не появляется

Существуют ли другие способы просмотра меню редактирования, навигации и ленты в этой базе данных доступа, чтобы я мог вносить в нее изменения?

1 Ответ

0 голосов
/ 16 мая 2018

Да, вы можете легко обойти такие меры "безопасности", используя OLE-автоматизацию.

Используйте следующий код из другой базы данных Access (или приложения VBA) 

Public Sub UnlockAccess()
    Dim pathToFile As String
    pathToFile = "C:\Path\To\My\File.accdb"
    Dim db As DAO.Database
    Set db = DBEngine.OpenDatabase(pathToFile)
    'Set some restrictive properties back to normal
    On Error Resume Next
    db.Properties!StartUpShowStatusBar = True
    db.Properties!AllowFullMenus = True
    db.Properties!AllowShortcutMenus = True
    db.Properties!AllowBuiltInToolbars = True
    db.Properties!AllowSpecialKeys = True
    db.Properties!AllowToolbarChanges = True
    db.Properties!AllowByPassKey = True
    db.Close
    On Error GoTo 0
    Stop 'You can open up the database using the shift bypass key here, and enable whatever you want'
    Dim app As New Access.Application
    app.OpenCurrentDatabase pathToFile
    app.Visible = True
    app.UserControl = True
    app.DoCmd.SelectObject acTable, , True
End Sub

Альтернативным способом изменения безопасности является изменение ограничительного кода VBA. Если вы не можете открыть редактор непосредственно из файла, вы можете открыть другой файл, установить ссылку на файл, который вы хотите изменить, и изменить его оттуда.

...