Код Excel / VBA игнорирует введенные аргументы - PullRequest
Новая
       25

Код Excel / VBA игнорирует введенные аргументы

0 голосов
/ 24 января 2019

У меня есть саб VBA, который при необходимости должен загружаться в модули пользовательского кода.Моя проблема в том, что когда я передаю («ModuleA», «. Bas»), код возвращает «ModuleB».ModuleB не существует (был удален) в указанном пути к файлу.

Как этот код может вернуть несуществующий файл, если ему специально передано другое значение?Переменная 'filepath' содержит правильный путь, и он правильно передается в оператор импорта.

Кроме того, оператор "Remove" не удаляет переданный ему модуль.

IЯ никогда не сталкивался с подобной проблемой и теряюсь в том, что делать.

Что я пробовал: Перезапуск Excel / PC, переименование модулей для изменения пути, добавление кода для удаления модулей в конце подпрограммы. 

    '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''SJH
'LoadModule
'
'Loads in a module with a specified name from the BigData Directory
'
'extension includes the ., so .frm or .bas
'
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Sub LoadModule(ByVal ModuleName As String, ByVal extension As String)
    ThisWorkbook.Activate
    Err.Clear
     'handle errors in-line...
    On Error Resume Next

    'include reference to "Microsoft Visual Basic for Applications Extensibility"
    Dim vbproj As VBIDE.VBProject
    Dim vbc As VBIDE.VBComponent
    Dim filepath As String

    filepath = ("\\uslafnas01\GE_LAB\BigData\" & ModuleName & extension)
    Set vbproj = ActiveWorkbook.VBProject

    'Error will occur if component with this name is not in the project
    Set vbc = vbproj.VBComponents(ModuleName)

    If Err.Number <> 0 Then
        Err.Clear
        'so add it...
        vbproj.VBComponents.Import filepath
        If Err.Number <> 0 Then
           MsgBox ("Could not import " & ModuleName & " Module: " & filepath)
        End If
    Else
        'no error - vbc should be valid object
        'remove existing version first before adding new version
        vbproj.VBComponents.Remove vbc
        vbproj.VBComponents.Import filepath
        If Err.Number <> 0 Then
            MsgBox ("New " & ModuleName & " couldn't replace old " & ModuleName & " Module " & filepath)
        End If
    End If


    'Set vbc = Nothing
    'Set vbproj = Nothing


End Sub

1 Ответ

0 голосов
/ 24 января 2019

Имя модуля определяется не именем его файла, а скрытым атрибутом VB_Name, который можно увидеть, открыв модуль, скажем, в блокноте.

Если вы откроете ModuleA.bas в Блокноте, я подозреваю, вы увидите это в самой первой строке, над Option Explicit: 

Attribute VB_Name = "ModuleB"

Имя файла не имеет значения, именно этот атрибут определяет программное имя модуля VBA..

Атрибуты модуля и члена не могут быть просмотрены или отредактированы (напрямую) в VBE.

...