Остановить добавление пустых строк в несколько столбцов ListBox

Question

У меня есть список с шестью столбцами, который я добавляю, когда пользователь выбирает посещение #, которое соответствует диапазону («A2») в моей рабочей таблице.Данные добавляются, но также будут добавлять пустые строки каждый раз, когда что-то добавляется в столбец.Вот что у меня есть.У меня нет пустых строк с соответствующим номером, поэтому я не уверен, почему он добавляет пробелы.Проверьте изображение для моих данных Excel.

Private Sub cboVisitNo_Click()
    Dim j As Integer, k As Integer, i As Integer

    Worksheets("Biopsy Log").Select
    Me.lstBNum.Clear
    i = 0
    For j = 1 To Range("A2", Range("A1").End(xlDown)).Rows.count 
        If Range("A2", Range("A2").End(xlDown)).Cells(j) = Me.cboVisitNo.Value Then
            With Me.lstBNum
                    For k = 0 To 5
                        .AddItem
                        .List(i, k) = Range("A" & j + 1).Offset(0, k)  
                    Next            
            End With
            i = i + 1  
        End If
    Next
End Sub

Answer 1

Не проверено:

Private Sub cboVisitNo_Click()
    Dim j As Long, k As Long, i As Long
    Dim c As Range

    Me.lstBNum.Clear
    i = 0
    With Worksheets("Biopsy Log")
        For Each c In .Range(.Range("A2"), .Cells(.Rows.Count, 1).End(xlUp)).Cells 
            If c.Value = Me.cboVisitNo.Value Then
                Me.lstBNum.AddItem '<< edit  ###
                For k = 0 To 5
                    Me.lstBNum.List(i, k) = c.Offset(0, k)  
                Next            
                i = i + 1  
            End If
        Next c
    End With
End Sub