Как повторно использовать родительские значения в преобразовании xslt?

Question

У меня есть глубоко вложенный XML-файл, и я хочу преобразовать его в плоский CSV.Поэтому я должен пойти по самому глубокому пути (здесь: availability) и повторно использовать значения от родителей (здесь: category, element).

Пример:

<market>
    <category>
        <type>kids</type>
    </category>
    <items>
        <element>
            <name>police car</name>
            <type>toy</type>
            <color>blue</color>
            <availability>
                <stock cat="A" in="5"/>
                <stock cat="B" in="2"/>
            </availability>
        </element>
        </element>
            ...
        </element>
    </items>
</market>

Требуемый вывод CSV:

kids,police car, toy, blue, A, 5
kids,police car, toy, blue, B, 2

Обратите внимание, как значение kids копируется в каждую результирующую строку element, и как каждый element копируется в каждый availability просмотр.

Я смотрел следующим образом, но, конечно, это не дает желаемого результата.Потому что я не знаю, как:

• правильно итерировать вложенные дочерние элементы

• объединять значения как csv, получая значения, найденные родителями

    <?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" omit-xml-declaration="yes" indent="no"/>
    <xsl:template match="market">
        <xsl:for-each select="//category">
            <xsl:value-of select="type"/>
        </xsl:for-each>

        <xsl:for-each select="//items//element">
            <xsl:value-of select="name"/>
            <xsl:value-of select="type"/>
            <xsl:value-of select="color"/>
        </xsl:for-each>

        <xsl:for-each select="//items//element//availability//stock">
            <xsl:value-of select="//@cat"/>
            <xsl:value-of select="//@in"/>
        </xsl:for-each>
    </xsl:template>

Следующее может работать, но я не знаю, так ли это:

<xsl:template match="market">
    <xsl:variable name="ctype">
        <xsl:value-of select="market/category/type"/>
    </xsl:variable>

    <xsl:for-each select="//items//element">
    <xsl:variable name="elem">
        <xsl:text>;</xsl:text>
        <xsl:value-of select="copy-of(.)!(.//name, .//type, .//color)" separator=";"/>
    </xsl:variable>

    <!-- nesting for-each -->
    <xsl:for-each select="availability//stock">
        <xsl:copy-of select="$elem"/>
        <xsl:text>;</xsl:text>
        <xsl:value-of select="copy-of(.)!(.//@cat, .//@in)" separator=";"/>
    </xsl:for-each>
    </xsl:for-each>
</xsl:template>

Answer 1

Я обычно пишу шаблон, соответствующий тем элементам, которые отображаются в линию, и выбираю другие значения по мере необходимости с помощью навигации XPath:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="3.0">

  <xsl:output method="text"/>

  <xsl:template match="/">
    <xsl:apply-templates select="//availability/stock"/>
  </xsl:template>


  <xsl:template match="stock">
      <xsl:value-of select="ancestor::market/category/type, ancestor::element!(name, type, color), @cat, @in" separator=", "/>
      <xsl:text>&#10;</xsl:text>
  </xsl:template>

</xsl:stylesheet>

Это позволяет получить компактную и четкую запись о том, какие значения составляют строку в файле CSV.

https://xsltfiddle.liberty -development.net / jyH9rM9

Статическая информация заголовка, такая как category/type, также может храниться в глобальной переменной:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="3.0">

  <xsl:output method="text"/>

  <xsl:variable name="category-type" select="market/category/type"/>

  <xsl:template match="/">
    <xsl:apply-templates select="//availability/stock"/>
  </xsl:template>


  <xsl:template match="stock">
      <xsl:value-of select="$category-type, ancestor::element!(name, type, color), @cat, @in" separator=", "/>
      <xsl:text>&#10;</xsl:text>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty -development.net / jyH9rM9 / 1

Третий способ в XSLT 3 - это сбор значений декларативным способом с использованием аккумуляторов:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    version="3.0">

  <xsl:mode use-accumulators="#all"/>

  <xsl:output method="text"/>

  <xsl:accumulator name="cat-type" as="xs:string?" initial-value="()">
      <xsl:accumulator-rule match="market/category/type" select="string()"/>
  </xsl:accumulator>

  <xsl:accumulator name="element-name" as="xs:string?" initial-value="()">
      <xsl:accumulator-rule match="item/element" select="()"/>
      <xsl:accumulator-rule match="items/element/name" select="string()"/>
  </xsl:accumulator>

  <xsl:accumulator name="element-type" as="xs:string?" initial-value="()">
      <xsl:accumulator-rule match="item/element" select="()"/>
      <xsl:accumulator-rule match="items/element/type" select="string()"/>
  </xsl:accumulator>

  <xsl:accumulator name="element-color" as="xs:string?" initial-value="()">
      <xsl:accumulator-rule match="item/element" select="()"/>
      <xsl:accumulator-rule match="items/element/color" select="string()"/>
  </xsl:accumulator>

  <xsl:template match="/">
    <xsl:apply-templates select="//availability/stock"/>
  </xsl:template>

  <xsl:template match="stock">
      <xsl:value-of select="accumulator-before('cat-type'), accumulator-before('element-name'), accumulator-before('element-type'), accumulator-before('element-color'), @cat, @in" separator=", "/>
      <xsl:text>&#10;</xsl:text>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty -development.net / jyH9rM9 / 2

Это имеет то преимущество, что вы можете адаптировать его к потоковой передаче с некоторыми изменениями, так как вы можете преобразовывать огромные входные данные с помощью Saxon 9.8 EE, не сохраняя полное дерево ввода XML в памяти:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    version="3.0">

    <xsl:mode use-accumulators="#all" />

    <xsl:output method="text"/>

    <xsl:accumulator name="cat-type" as="xs:string?" initial-value="()" streamable="yes">
        <xsl:accumulator-rule match="market/category/type/text()" select="string()"/>
    </xsl:accumulator>

    <xsl:accumulator name="element-name" as="xs:string?" initial-value="()" streamable="yes">
        <xsl:accumulator-rule match="item/element" select="()"/>
        <xsl:accumulator-rule match="items/element/name/text()" select="string()"/>
    </xsl:accumulator>

    <xsl:accumulator name="element-type" as="xs:string?" initial-value="()" streamable="yes">
        <xsl:accumulator-rule match="item/element" select="()"/>
        <xsl:accumulator-rule match="items/element/type/text()" select="string()"/>
    </xsl:accumulator>

    <xsl:accumulator name="element-color" as="xs:string?" initial-value="()" streamable="yes">
        <xsl:accumulator-rule match="item/element" select="()"/>
        <xsl:accumulator-rule match="items/element/color/text()" select="string()"/>
    </xsl:accumulator>

    <xsl:template match="/">
        <xsl:apply-templates select="outermost(//availability/stock)"/>
    </xsl:template>

    <xsl:template match="stock">
        <xsl:value-of select="accumulator-before('cat-type'), accumulator-before('element-name'), accumulator-before('element-type'), accumulator-before('element-color'), @cat, @in" separator=", "/>
        <xsl:text>&#10;</xsl:text>
    </xsl:template>

</xsl:stylesheet>

Answer 2

Попробуйте это:

<xsl:strip-space elements="*"/>
<xsl:template match="market">
    <xsl:for-each select=".//stock">
        <xsl:value-of select="ancestor::market/category/type
            |ancestor::market/items/element/name
            |ancestor::market/items/element/type
            |ancestor::market/items/element/color
            |@cat
            |@in" separator=", "/>
    <xsl:text>&#xa;</xsl:text>
    </xsl:for-each>
</xsl:template>

Вывод

kids, police car, toy, blue, A, 5
kids, police car, toy, blue, B, 2