Как мне прочитать 64-битные значения реестра из VBScript, работающего как задача msi после установки? - PullRequest
Новая
       29

Как мне прочитать 64-битные значения реестра из VBScript, работающего как задача msi после установки?

7 голосов
/ 05 августа 2009

Мне нужно прочитать расположение папки временных файлов ASP.NET из VBScript как часть задачи после установки в программе установки, созданной с помощью проекта развертывания Visual Studio 2008.

Я думал, что сделаю что-то вроде этого: 

Set oShell = CreateObject("Wscript.Shell")
strPath = oShell.RegRead("HKLM\SOFTWARE\Microsoft\ASP.NET\2.0.50727.0\Path")

, а затем объединить strPath с "\ Temporary ASP.NET Files" и покончить с этим.

В системе x64, однако, я получаю значение из WOW6432Node (HKLM \ SOFTWARE \ Wow6432Node \ Microsoft \ ASP.NET \ 2.0.50727.0), который дает мне 32-битный путь к каркасу (C: \ Windows \ Microsoft.NET \ Framework \ v2.0.50727), но в системе x64 мне действительно нужен 64-битный путь, например C: \ Windows \ Microsoft.NET \ Framework64 \ v2.0.50727.

Я понимаю, что это происходит потому, что файл .vbs запускается с использованием 32-разрядного хоста сценария, поскольку родительский процесс (установщик) сам является 32-разрядным.

Как запустить сценарий с использованием 64-разрядного узла сценария или - как я могу прочитать 64-разрядные значения, даже если сценарий выполняется с использованием узла 32-разрядного сценария?

Ответы [ 4 ]

9 голосов
/ 05 августа 2009

Не уверен насчет запуска версии хоста 64-битного скрипта, но вы должны иметь доступ к 64-битному реестру с хоста 32-битного скрипта, используя класс WMI StdRegProv, например так : 

Const HKEY_LOCAL_MACHINE = &H80000002
sPath = ReadRegStr (HKEY_LOCAL_MACHINE, "SOFTWARE\Microsoft\ASP.NET\2.0.50727.0", "Path", 64)
WScript.Echo sPath

' Reads a REG_SZ value from the local computer's registry using WMI.
' Parameters:
'   RootKey - The registry hive (see http://msdn.microsoft.com/en-us/library/aa390788(VS.85).aspx for a list of possible values).
'   Key - The key that contains the desired value.
'   Value - The value that you want to get.
'   RegType - The registry bitness: 32 or 64.
'
Function ReadRegStr (RootKey, Key, Value, RegType)
    Dim oCtx, oLocator, oReg, oInParams, oOutParams

    Set oCtx = CreateObject("WbemScripting.SWbemNamedValueSet")
    oCtx.Add "__ProviderArchitecture", RegType

    Set oLocator = CreateObject("Wbemscripting.SWbemLocator")
    Set oReg = oLocator.ConnectServer("", "root\default", "", "", , , , oCtx).Get("StdRegProv")

    Set oInParams = oReg.Methods_("GetStringValue").InParameters
    oInParams.hDefKey = RootKey
    oInParams.sSubKeyName = Key
    oInParams.sValueName = Value

    Set oOutParams = oReg.ExecMethod_("GetStringValue", oInParams, , oCtx)

    ReadRegStr = oOutParams.sValue
End Function

Примечание: я сейчас нахожусь под 32-битной ОС, поэтому не могу проверить, работает ли этот пример. Остерегайтесь ошибок: -)

См. Также Запрос данных WMI на 64-битной платформе Статья MSDN для получения дополнительной информации по этому вопросу.

0 голосов
/ 20 сентября 2018

Используя документированный подход Microsoft, ответ Хелен абсолютно верен.

Однако в соответствии с моими собственными тестами выясняется, что достаточно указать флаг контекста __ProviderArchitecture только в тот момент, когда установлено соединение с поставщиком StdRegProv.
Это значительно упрощает задачу, поскольку только настройка провайдера должна быть заключена в отдельную функцию, в противном случае можно использовать обычный API. 

set reg64 = MakeRegLocator(64)
reg64.GetStringValue , "SOFTWARE\Microsoft\ASP.NET\2.0.50727.0", "Path", path

WScript.Echo path

' Establish a connection to the local 32 or 64 bit registry hive as requested.
' Parameters:
'   RegType - The registry bitness: 32 or 64.
function MakeRegLocator(bitness)
    set ctx = CreateObject("WbemScripting.SWbemNamedValueSet")
    ctx.Add "__ProviderArchitecture", bitness

    set locator = CreateObject("Wbemscripting.SWbemLocator")
    set services = locator.ConnectServer("", "root\default", "", "", , , , ctx)
    set reg = services.Get("StdRegProv")

    set MakeRegLocator = reg
end function
0 голосов
/ 10 июля 2014

Пожалуйста, проверьте это:

Set oShell = CreateObject ("Wscript.Shell") strPath = oShell.RegRead ("HKLM64 \ SOFTWARE \ Microsoft \ ASP.NET \ 2.0.50727.0 \ Path")

https://www.autoitscript.com/autoit3/docs/functions/RegRead.htm

0 голосов
/ 22 июля 2010

Я думаю, что-то вроде этого, но я не разобрался, как обрабатывать выходные значения. 

strComputer = "."
Const HKLM = &h80000002
Set objCtx = CreateObject("WbemScripting.SWbemNamedValueSet")
objCtx.Add "__ProviderArchitecture", 64
objCtx.Add "__RequiredArchitecture", TRUE
Set objLocator = CreateObject("Wbemscripting.SWbemLocator")
Set objServices = objLocator.ConnectServer("","root\default","","",,,,objCtx)
Set objStdRegProv = objServices.Get("StdRegProv") 

' Use ExecMethod to call the GetStringValue method
Set Inparams = objStdRegProv.Methods_("EnumValues").Inparameters
Inparams.Hdefkey = HKLM
Inparams.Ssubkeyname = "SOFTWARE\Microsoft\Microsoft SQL Server\Instance Names\SQL\"
'Inparams.Svaluename = "Logging"
set Outparams = objStdRegProv.ExecMethod_("EnumValues", Inparams,,objCtx)

'Show output parameters object and the registry value HKLM\SOFTWARE\
WScript.Echo Outparams.GetObjectText_
WScript.Echo "WMI Logging is set to  " & Outparams.SValue
...