Объединить поля, используя XML и XSLT в цикле

Question

У меня есть исходный XML-файл, который я хочу преобразовать в другой XML-файл с другим форматом.Мой исходный XML-файл использует атрибуты (я думаю, исправьте меня, если я здесь ошибаюсь), и целевой формат XML должен быть простыми родительскими и дочерними XML-тегами.У меня нет проблем с прямым подходом.

Однако мне нужно найти способ объединить 2 или более полей в один элемент с помощью XSLT.Я попытался использовать переменные, затем конкатенировать их, однако, у меня есть некоторые проблемы с переменными, и они могут быть назначены только один раз.

Мой XML такой:

<?xml version="1.0" encoding="UTF-8"?>
<Document xmlns="http://www.taleo.com/ws/integration/toolkit/2005/07" xmlns:ns1="http://www.taleo.com/ws/integration/toolkit/2005/07" xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"><Attributes><Attribute name="count">1</Attribute><Attribute name="duration">0:00:00.109</Attribute><Attribute name="entity">SourcingRequest</Attribute><Attribute name="mode">XML</Attribute><Attribute name="version">http://www.taleo.com/ws/tee800/2009/01</Attribute></Attributes><Content>
<ExportXML xmlns="http://www.taleo.com/ws/integration/toolkit/2005/07">
    <record>
        <field name="Title">Project Analyst</field>
        <field name="Position_ID">64057</field>
        <field name="RequisitionNumber">180767</field>
        <field name="LocationCode">HQ</field>
        <field name="LocationName">Headquarters</field>
        <field name="LocationCountry">Country</field>
        <field name="LocationCity">City</field>
    </record>
</ExportXML></Content></Document>

Тогда мой XSL похожэто:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0" xmlns:itk="http://www.taleo.com/ws/integration/toolkit/2005/07">
  <xsl:output method="xml" encoding="UTF-8" omit-xml-declaration="yes" cdata-section-elements="DescriptionInternal DescriptionExternal QualificationExternal QualificationInternal"/>
  <xsl:template match="text()"/>
  <xsl:template match="itk:record">
    <xsl:element name="Job">
        <xsl:for-each select="itk:field">
            <!-- Set variables -->
            <xsl:variable name="location_code">
              <xsl:if test="@name='LocationCode'">
                <xsl:value-of select="." />
              </xsl:if>
            </xsl:variable>
            <xsl:variable name="location_name">
              <xsl:if test="@name='LocationName'">
                <xsl:value-of select="." />
              </xsl:if>
            </xsl:variable>
            <xsl:variable name="location_country">
              <xsl:if test="@name='LocationCountry'">
                <xsl:value-of select="." />
              </xsl:if>
            </xsl:variable>
            <xsl:variable name="location_city">
              <xsl:if test="@name='LocationCity'">
                <xsl:value-of select="." />
              </xsl:if>
            </xsl:variable>
            <xsl:choose>
              <xsl:when test="@name='LocationCode' or @name='LocationName' or @name='LocationCountry' or @name='LocationCity'">
                <xsl:if test="@name='LocationCity'">
                  <xsl:element name="Location">
                    <xsl:value-of select="concat($location_code,$location_name,$location_country,$location_city)" />
                  </xsl:element>
                  <xsl:element name="LocationCode">
                    <xsl:value-of select="$location_code" />
                  </xsl:element>
                  <xsl:element name="LocationName">
                    <xsl:value-of select="$location_code" />
                  </xsl:element>
                </xsl:if>
              </xsl:when>
              <xsl:otherwise>
                <!-- Set variables. -->
                <xsl:variable name="NodeName" select="@name"/>
                <xsl:element name="{@name}">                
                    <xsl:value-of select="."/>
                </xsl:element>                
              </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>             
    </xsl:element>
  </xsl:template>
</xsl:stylesheet>

Тем не менее, мой вывод выглядит следующим образом:

<Job>
   <Title>Project Analyst</Title>
   <Position_ID>64057</Position_ID>
   <RequisitionNumber>180767</RequisitionNumber>
   <Location>City</Location>
</Job>

Но мой желаемый вывод должен быть таким:

<Job>
   <Title>Project Analyst</Title>
   <Position_ID>64057</Position_ID>
   <RequisitionNumber>180767</RequisitionNumber>
   <Location>HQ Headquarters Country City</Location>
</Job>    

Если мое предположениеХорошо, я думаю, что цикл сбрасывает значения переменных.То, что было последним, будет значением.

Есть ли другой способ добиться желаемого результата.Мои параметры ограничены XSL, хотя мой исходный файл можно изменить в формат CSV.

Благодарим за любую помощь.

Answer 1

Есть ли причина, по которой вы не можете просто сделать:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:itk="http://www.taleo.com/ws/integration/toolkit/2005/07" 
exclude-result-prefixes="itk">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" omit-xml-declaration="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/itk:Document">
    <xsl:apply-templates select="itk:Content/itk:ExportXML/itk:record"/>
</xsl:template>

<xsl:template match="itk:record">
    <Job>
        <Title>
            <xsl:value-of select="itk:field[@name='Title']" />
        </Title>
        <Position_ID>
            <xsl:value-of select="itk:field[@name='Position_ID']" />
        </Position_ID>
        <RequisitionNumber>
            <xsl:value-of select="itk:field[@name='RequisitionNumber']" />
        </RequisitionNumber>
        <Location>
            <xsl:value-of select="itk:field[@name='LocationCode']" />
            <xsl:text> </xsl:text>
            <xsl:value-of select="itk:field[@name='LocationName']" />
            <xsl:text> </xsl:text>
            <xsl:value-of select="itk:field[@name='LocationCountry']" />
            <xsl:text> </xsl:text>
            <xsl:value-of select="itk:field[@name='LocationCity']" />
        </Location>
    </Job>    
</xsl:template>

</xsl:stylesheet>

---

Или, если используется XSLT 2.0, еще проще:

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xpath-default-namespace="http://www.taleo.com/ws/integration/toolkit/2005/07" >
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" omit-xml-declaration="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/Document">
    <xsl:apply-templates select="Content/ExportXML/record"/>
</xsl:template>

<xsl:template match="record">
    <Job>
        <xsl:for-each select="field[not(starts-with(@name, 'Location'))]">
            <xsl:element name="{@name}">
                <xsl:value-of select="." />
            </xsl:element>
        </xsl:for-each>
        <Location>
            <xsl:value-of select="field[starts-with(@name, 'Location')]" />
        </Location>
    </Job>    
</xsl:template>

</xsl:stylesheet>