Добавить строки с 0 для пропущенных значений в таблице данных

Question

У меня есть набор данных, подсчитывающий вхождения бинов, например:

1 10
2 15
3 1
5 50
8 990

Как вы видите, я пропускаю бины в первом столбце.Поскольку я хочу построить эти данные, я ищу способ добавить эти пропущенные значения со значением 0 во втором столбце, например, если я знаю, что мои ячейки доходят до 10:

1 10
2 15 
3 1
4 0
5 50
6 0
7 0
8 990
9 0
10 0

Iищу решение для unix / bash, так как оно подходит для моего конвейера и мои файлы довольно большие, но, возможно, R больше подходит для этого?

Answer 1

$ awk '{n[$1]=$2} END{for (i=1;i<=10;i++) print i,n[i]+0}' file
1 10
2 15
3 1
4 0
5 50
6 0
7 0
8 990
9 0
10 0

Answer 2

еще awk

$ awk -v mx=10 '{while(++k<$1) print k,0}1; 
            END {while(k++<mx) print k,0}' file

это заполнит первые записи, если они также будут отсутствовать.

Answer 3

Использование Bash и join:

$ join -a 1 --nocheck-order -e 0 -o 1.1,2.2 <(seq 10) file

Вывод:

1 10
2 15
3 1
4 0
5 50
6 0
7 0
8 990
9 0
10 0

Answer 4

мы можем объединить seq и awk, чтобы упростить задачу:

awk 'NR==FNR{a[$1]=$0;next}{print $1 in a?a[$1]:$1 FS 0}' file <(seq 10)

Вы также можете сделать это:

 awk 'NR==FNR{a[$1]=$0;next}{print $1 in a?a[$1]:$0}' f <(seq -f '%g 0' 10)

Проверка с вашими данными:

kent$  cat f
1 10
2 15
3 1
5 50
8 990

kent$  awk 'NR==FNR{a[$1]=$0;next}{print $1 in a?a[$1]:$1 FS 0}' f <(seq 10)
1 10
2 15
3 1
4 0
5 50
6 0
7 0
8 990
9 0
10 0

Answer 5

РЕДАКТИРОВАТЬ: Благодаря karafaka сэр, добавление решений, которые будут также захватывать цифры самой первой строки.

awk -v value=10 '$1-prev>1{while(++prev<$1){print prev,"0"}} {prev=$1;print} END{if(prev<value){while(prev<=value){print prev,"0";prev++}}}'  Input_file

Допустим, следующий файл Input_file:

cat Input_file
3 10
4 15
7 1
9 50
19 990

Затем после выполнения кода выше мы получим следующий вывод.

1 0
2 0
3 10
4 15
5 0
6 0
7 1
8 0
9 50
10 0
11 0
12 0
13 0
14 0
15 0
16 0
17 0
18 0
19 990

---

---

Не могли бы вы попробовать следующее.

awk -v value=10 'prev && $1-prev>1{while(++prev<$1){print prev,"0"}} {prev=$1;print} END{if(prev<value){while(prev<=value){print prev,"0";prev++}}}' Input_file

Добавлениене однолинейная форма решения тоже сейчас.

awk -v value=10 '
prev && $1-prev>1{
  while(++prev<$1){
    print prev,"0"
  }
}
{
  prev=$1
  print
}
END{
  if(prev<value){
    while(prev<=value){
      print prev,"0"
      prev++
    }
  }
}'  Input_file