Удалить пространства имен и заменить другим пространством имен - PullRequest
Новая
       8

Удалить пространства имен и заменить другим пространством имен

0 голосов
/ 17 сентября 2018

Мой вывод имеет пространства имен, но его следует удалить и заменить другим пространством имен.Возможно ли это?

В настоящее время у меня есть XSL: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
xmlns:wd="urn:com.workday.report/INT001"
xmlns:pi="urn:com.workday.report/INT001"
xmlns:xs="http://www.w3.org/2001/XMLSchema">

<xsl:output indent="yes" method="xml" omit-xml-declaration="yes"/>
<xsl:strip-space elements="*" />

<xsl:template match="wd:RD">
    <pi:PEE>
        <xsl:for-each-group select="wd:RE" group-by="wd:PG">
            <pi:PG>
                <pi:X>
                    <pi:PGID><xsl:value-of select="wd:PGID"/></pi:PGID>
                    <pi:DF><xsl:value-of select="current-dateTime() - xs:dayTimeDuration('P1D')"/></pi:DF>
                    <pi:DE><xsl:value-of select="current-dateTime()"/></pi:DE>
                </pi:X>
                <xsl:for-each select="current-group()">
                <xsl:call-template name="Content"/>                    
                </xsl:for-each>
            </pi:PG>
        </xsl:for-each-group>
    </pi:PEE>
</xsl:template>

<xsl:template name="Content">
<pi:EE>  
    <pi:L1>
        <pi:EID><xsl:value-of select="wd:EID"/></pi:EID>
        <pi:PGID><xsl:value-of select="wd:PGID"/></pi:PGID>
        <pi:PG><xsl:value-of select="wd:PG"/></pi:PG>
    </pi:L1>
    <pi:L2>
        <pi:EE><xsl:value-of select="wd:EE"/></pi:EE>
        <pi:BD><xsl:value-of select="wd:BD"/></pi:BD>
        <pi:GDR><xsl:value-of select="wd:GDR"/></pi:GDR>
    </pi:L2>
</pi:EE>  
</xsl:template>
</xsl:stylesheet>

и XML: 

<wd:RD xmlns:wd="urn:com.workday.report/INT001">
<wd:RE>
<wd:PG>AR</wd:PG>
<wd:PGID>10102</wd:PGID>
<wd:EID>0001</wd:EID>
<wd:EE>Emp1</wd:EE>
<wd:GDR>M</wd:GDR>
<wd:BD>1900-01-01</wd:BD>
</wd:RE>
<wd:RE>
<wd:PG>OR</wd:PG>
<wd:PGID>10101</wd:PGID>
<wd:EID>0002</wd:EID>
<wd:EE>Emp2</wd:EE>
<wd:GDR>F</wd:GDR>
<wd:BD>1900-02-02</wd:BD>
</wd:RE>
<wd:RE>
<wd:PG>OR</wd:PG>
<wd:PGID>10101</wd:PGID>
<wd:EID>0003</wd:EID>
<wd:EE>Emp3</wd:EE>
<wd:BD>1900-03-03</wd:BD>
</wd:RE>
</wd:RD>

Мой желаемый вывод: 

<pi:PEE xmlns:pi="urn:com.workday/picof">
<pi:PG>
   <pi:X>
     <pi:PCID>101</pi:PCID>
     <pi:PGID>10101</pi:PGID>
  </pi:X>
  <pi:EE>
     <pi:L1>
        <pi:EID>0002</pi:EID>
        <pi:PGID>10101</pi:PGID>
        <pi:PG>OR</pi:PG>
     </pi:L1>
     <pi:L2>
        <pi:EE>Emp2</pi:EE>
        <pi:BD>1900-02-02</pi:BD>
        <pi:GDR>F</pi:GDR>
     </pi:L2>
  </pi:EE>
  <pi:EE>
     <pi:L1>
        <pi:EID>0003</pi:EID>
        <pi:PGID>10101</pi:PGID>
        <pi:PG>OR</pi:PG>
     </pi:L1>
     <pi:L2>
        <pi:EE>Emp3</pi:EE>
        <pi:BD>1900-03-03</pi:BD>            
     </pi:L2>
  </pi:EE>
</pi:PG>
<pi:PG>
  <pi:X>
     <pi:PCID>102</pi:PCID>
     <pi:PGID>10102</pi:PGID>
  </pi:X>
  <pi:EE>
     <pi:L1>
        <pi:EID>0001</pi:EID>
        <pi:PGID>10102</pi:PGID>
        <pi:PG>AR</pi:PG>
     </pi:L1>
     <pi:L2>
        <pi:EE>Emp1</pi:EE>
        <pi:BD>1900-01-01</pi:BD>
        <pi:GDR>M</pi:GDR>
     </pi:L2>
  </pi:EE>
</pi:PG>
</pi:PEE>

Я хочу удалить xmlns:wd="urn:com.workday.report/INT001" xmlns:pi="urn:com.workday.report/INT001" xmlns:xs="http://www.w3.org/2001/XMLSchema" и заменить на xmlns:pi="urn:com.workday/picof"

Также, если вы заметили, все пустые элементы также должны быть удалены.Для Emp3 ГДР пуст.

Ответы [ 2 ]

0 голосов
/ 17 сентября 2018

Я думаю, что вы можете просто сократить код, используя xpath-default-namespace, а затем, поскольку вы хотите выводить элементы результата только для тех элементов ввода, которые существуют, вы можете использовать apply-templates по мере необходимости для отображения элементов ввода в результат элементы с шаблонами: 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xpath-default-namespace="urn:com.workday.report/INT001"
    xmlns:pi="urn:com.workday/picof"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="RD">
      <pi:PEE>
          <xsl:for-each-group select="RE" group-by="PG">
              <pi:PG>
                  <pi:X>
                    <pi:PGID><xsl:value-of select="PGID"/></pi:PGID>
                    <pi:DF><xsl:value-of select="current-dateTime() - xs:dayTimeDuration('P1D')"/></pi:DF>
                    <pi:DE><xsl:value-of select="current-dateTime()"/></pi:DE>
                  </pi:X>
                  <xsl:apply-templates select="current-group()"/>
              </pi:PG>
          </xsl:for-each-group>
      </pi:PEE>
  </xsl:template>

  <xsl:template match="RE">
      <pi:EE>
          <pi:L1>
              <xsl:apply-templates select="EID, PGID, PG"/>
          </pi:L1>
          <pi:L2>
              <xsl:apply-templates select="EE, BD, GDR"/>
          </pi:L2>
      </pi:EE>
  </xsl:template>

  <xsl:template match="RE/*">
      <xsl:element name="pi:{local-name()}">
          <xsl:apply-templates/>
      </xsl:element>
  </xsl:template>

</xsl:stylesheet>

Преобразует представленные вами данные в https://xsltfiddle.liberty -development.net / 6qVRKwH в результат 

<pi:PEE xmlns:pi="urn:com.workday/picof">
   <pi:PG>
      <pi:X>
         <pi:PGID>10102</pi:PGID>
         <pi:DF>2018-09-16T17:49:47.15+02:00</pi:DF>
         <pi:DE>2018-09-17T17:49:47.15+02:00</pi:DE>
      </pi:X>
      <pi:EE>
         <pi:L1>
            <pi:EID>0001</pi:EID>
            <pi:PGID>10102</pi:PGID>
            <pi:PG>AR</pi:PG>
         </pi:L1>
         <pi:L2>
            <pi:EE>Emp1</pi:EE>
            <pi:BD>1900-01-01</pi:BD>
            <pi:GDR>M</pi:GDR>
         </pi:L2>
      </pi:EE>
   </pi:PG>
   <pi:PG>
      <pi:X>
         <pi:PGID>10101</pi:PGID>
         <pi:DF>2018-09-16T17:49:47.15+02:00</pi:DF>
         <pi:DE>2018-09-17T17:49:47.15+02:00</pi:DE>
      </pi:X>
      <pi:EE>
         <pi:L1>
            <pi:EID>0002</pi:EID>
            <pi:PGID>10101</pi:PGID>
            <pi:PG>OR</pi:PG>
         </pi:L1>
         <pi:L2>
            <pi:EE>Emp2</pi:EE>
            <pi:BD>1900-02-02</pi:BD>
            <pi:GDR>F</pi:GDR>
         </pi:L2>
      </pi:EE>
      <pi:EE>
         <pi:L1>
            <pi:EID>0003</pi:EID>
            <pi:PGID>10101</pi:PGID>
            <pi:PG>OR</pi:PG>
         </pi:L1>
         <pi:L2>
            <pi:EE>Emp3</pi:EE>
            <pi:BD>1900-03-03</pi:BD>
         </pi:L2>
      </pi:EE>
   </pi:PG>
</pi:PEE>

Это имеет другой порядок для элементов pi:PG, но вы не объяснили, почему ваш результат имеет эти элементы в другом порядке, чем соответствующие элементы ввода, и я не вижу никакой попытки в вашем опубликованном XSLT изменить Порядок, поэтому я опубликую это как предложение, если порядок неправильный, вам нужно отредактировать свой вопрос и объяснить, каким образом вы хотите изменить порядок или отсортировать созданные вами группы.

0 голосов
/ 17 сентября 2018

для удаления дополнительного пространства имен просто добавьте exclude-result-prefixes="wd xs" в декларации таблицы стилей как: 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
    xmlns:wd="urn:com.workday.report/INT001"
    xmlns:pi="urn:com.workday.report/INT001"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="wd xs">

Также для удаления пустых элементов вы можете добавить условие, как показано ниже, сначала проверьте, что в элементе есть данные, чем в элементе copy. 

<xsl:if test="wd:GDR[node()]"><pi:GDR><xsl:value-of select="wd:GDR"/></pi:GDR></xsl:if>
...