Список BUKRS, который может видеть текущий пользователь - PullRequest
Новая
       19

Список BUKRS, который может видеть текущий пользователь

0 голосов
/ 19 ноября 2018

Есть ли способ получить список всех BUKRS, которые может видеть текущий пользователь?

Я хочу использовать этот список в качестве фильтра в открытых SQL. Представьте, что результат метода, который я ищу, сохранил результат в bk_list. Тогда я мог бы использовать bk_list так: 

SELECT * FROM some_table WHERE bukrs IN bk_list

Ответы [ 2 ]

0 голосов
/ 19 ноября 2018

Еще один способ сделать это, основываясь на классе CL_AUTH_OBJECTS_TO_SQL (> = 7.50), здесь программа считывает рейсы от авторизованных авиакомпаний-перевозчиков: 

DATA(authsql) = cl_auth_objects_to_sql=>create_for_open_sql( ).

authsql->add_authorization_object( EXPORTING
    iv_authorization_object = 'S_CARRID'
    it_activities = VALUE #( ( auth_field = 'ACTVT' value = '03' ) )
    it_field_mapping = VALUE #(
      ( auth_field = 'CARRID'
        view_field = VALUE #( table_ddic_name = 'SFLIGHT' field_name = 'CARRID' ) ) ) ).

DATA(where) = authsql->get_sql_condition( ).

SELECT * FROM sflight INTO TABLE @data(sflights) WHERE (where).
0 голосов
/ 19 ноября 2018

Боюсь, вы можете сделать это один за другим.Примерно: 

SELECT bukrs
       INTO TABLE @DATA(lt_t001)
       FROM t001
       WHERE ... . "Selection critera, if necessary

LOOP AT lt_t001
     ASSIGNING FIELD-SYMBOL(<ls_t001>).
  DATA(lv_tabix) = sy-tabix.
  AUTHORITY-CHECK OBJECT 'F_BKPF_BUK'
           ID 'BUKRS' FIELD <ls_t001>-bukrs
           ID 'ACTVT' FIELD '03'. "Here you need the proper activity (display '03' /change '02' / etc.)
  IF sy-subrc <> 0. "Auth check failed
    DELETE lt_t001 INDEX lv_tabix.
  ENDIF.
ENDLOOP.

В конце lt_t001 содержит только балансовые единицы, для которых у пользователя есть авторизация.

...