Проблема создания новой команды в ансамбле `array`

Question

Я хочу создать вспомогательную команду array values arrayName в качестве "оборотной стороны" команды "имена массивов".

Создать простой процесс просто:

proc array_values {arrayName} {
    upvar 1 $arrayName ary
    set values {}
    foreach {name value} [array get ary] {lappend values $value}
    return $values
}

array set a {foo bar baz qux}
puts [array_values a]           ;# => bar qux

Однако у меня возникают трудности при создании команды в пространстве имен ::tcl::array:

• первая домашняя работа:

  1. является array ансамблем пространства имен? Да.

     % namespace ensemble exists array
     1
     

  2. что такое пространство имен?

     % namespace ensemble configure array -namespace
     ::tcl::array
     

  3. Какие подкоманды?

     % namespace ensemble configure array -subcommands
     % namespace ensemble configure array -map
     anymore ::tcl::array::anymore donesearch ::tcl::array::donesearch exists ::tcl::array::exists get ::tcl::array::get names ::tcl::array::names nextelement ::tcl::array::nextelement set ::tcl::array::set size ::tcl::array::size startsearch ::tcl::array::startsearch statistics ::tcl::array::statistics unset ::tcl::array::unset
     

ОК, все хорошо, вар. Давайте добавим этот array_values proc в пространство имен

% namespace eval ::tcl::array {
    proc values {arrayName} {
        upvar 1 $arrayName ary
        set values {}
        foreach {name value} [array get ary] {lappend values $value}
        return $values
    }
}
% array set a {foo bar baz qux}
% puts [::tcl::array::values a]

can't set "values": variable is array

Откуда эта ошибка? Я попытался переименовать переменную «values» в proc для других имен, но она все равно выдает ошибку «variable is array».

---

примечание: я могу добавить первый ансамбль в процесс:

% namespace ensemble config array -map [list values ::array_values {*}[namespace ensemble config array -map]]
% array values a
bar qux

Но что не так с моей ::tcl::array::values процедурой?

Answer 1

Я хотел бы добавить, что, учитывая, что наличие возможно конфликтующих команд ансамбля является движущейся целью, исправление ансамбля может происходить повсюду, я видел, как разработчики ядра держат дополнительные команды ансамбля вне пространства имен ::tcl::array::*:

proc arrayValues {arrayName} {
    upvar 1 $arrayName ary
    set values {}
    foreach {name value} [array get ary] {lappend values $value}
    return $values
}

# implant "arrayValues" into [array] ensemble as "values"
namespace ensemble configure ::array -map \
    [dict replace [namespace ensemble configure ::array -map] \
     values [namespace which arrayValues]]

Таким образом, вам не нужно беспокоиться о непреднамеренных конфликтах разрешения (что бы это ни значило в Tcl, для начала).

Answer 2

Для любопытных это то, чем я закончил:

$ HOME / tcl / lib / monkeypatches / monkeypatches.tcl

# a set of useful additions to built-in ensembles

package provide monkeypatches 0.1

namespace eval ::monkeypatches {
    # https://wiki.tcl-lang.org/page/wrapping+commands
    proc append_subcommand {cmd subcmd procname} {
        set map [namespace ensemble configure $cmd -map]
        dict set map $subcmd [namespace which $procname]
        namespace ensemble configure $cmd -map $map
    }


    # array foreach
    # to be subsumed by https://core.tcl.tk/tips/doc/trunk/tip/421.md
    #
    # example:
    #   array set A {foo bar baz qux}
    #   array foreach {key val} A {puts "name=$key, value=$val"}
    #
    proc array_foreach {vars arrayName body} {
        if {[llength $vars] != 2} {
            error {array foreach: "vars" must be a 2 element list}
        }
        lassign $vars keyVar valueVar

        # Using the complicated `upvar 1 $arrayName $arrayName` so that any
        # error messages propagate up with the user's array name
        upvar 1 $arrayName $arrayName \
                $keyVar    key \
                $valueVar  value

        set sid [array startsearch $arrayName]
        # If the array is modified while a search is ongoing, the searchID will
        # be invalidated: wrap the commands that use $sid in a try block.
        try {
            while {[array anymore $arrayName $sid]} {
                set key [array nextelement $arrayName $sid]
                set value [set "${arrayName}($key)"]
                uplevel 1 $body
            }
            array donesearch $arrayName $sid
        } trap {TCL LOOKUP ARRAYSEARCH} {"" e} {
            return -options $e "detected attempt to modify the array while iterating"
        }
        return
    }
    append_subcommand ::array foreach array_foreach


    # array values arrayName
    # https://stackoverflow.com/q/53379995/7552
    #
    # example:
    #   array set x {foo bar baz qux}
    #   array get x             ;# => foo bar baz qux
    #   array names x           ;# => foo baz
    #   array values x          ;# => bar qux
    #
    proc array_values {arrayName} {
        upvar 1 $arrayName ary
        set values [list]
        array foreach {name value} ary {lappend values $value}
        return $values
    }
    append_subcommand ::array values array_values


    # info formalargs procName
    # https://core.tcl.tk/tips/doc/trunk/tip/65.md
    #
    # example:
    #   proc test {one {two 2} {three {3 4 5}} args} {return}
    #   info args test          ;# => one two three args
    #   info formalargs test    ;# => one {two 2} {three {3 4 5}} args
    #
    proc info_formalargs {procname} {
        # [info args] throws an error if $procname is not a procedure.
        return [lmap arg [info args $procname] {
            set has_d [info default $procname $arg value]
            if {$has_d} then {list $arg $value} else {set arg}
        }]
    }
    append_subcommand ::info formalargs info_formalargs
}

Со связанным с ним pkgIndex.tcl

И $ HOME / .tclshrc

set lib_dir [file join $env(HOME) tcl lib]
if {$lib_dir ni $auto_path} {lappend auto_path $lib_dir}
unset lib_dir
package require monkeypatches

Answer 3

Ваша команда set values {} выполняется в пространстве имен :: tcl :: array, поэтому она запускает команду :: tcl :: array :: set.Другими словами, это эквивалентно array set values {}.Таким образом, он делает значения массивом без членов.Затем команда lappend values $value завершается неудачно, так как значения в этот момент являются массивом.

Решение должно заключаться в использовании ::set values {}

Или вы можете полностью избежать этой проблемы, используя:

proc array_values {arrayName} {
    upvar 1 $arrayName ary
    return [lmap {name value} [get ary] {string cat $value}]
}