Экспорт последней строки в файл CSV с использованием VBScript

Question

Я все еще начинающий, когда дело доходит до сценариев, поэтому, пожалуйста, прости меня, если это простая ошибка с моей стороны.

Я пытаюсь отобразить последнюю строку в постоянно обновляемом файле CSV, используя сценарий VBS, который я создал и выполнил с помощью CMD.Я потянул и возился с кодом из нескольких источников.

Пока что я могу заставить его тянуть только верхний ряд и не могу понять, как переключить его на нижний.Мой код немного грубоват.Любая помощь будет принята с благодарностью.

Вот мой код:

Option Explicit
Dim objExcel
Dim excelPath
Dim workSheetCount
Dim counter
Dim currentWorkSheet
Dim usedRowsCount
Dim row
Dim top
Dim Cells
Dim curRow
Dim word


excelPath = "c:\Test\test.csv"

WScript.Echo "Reading Data from " & excelPath

Set objExcel = CreateObject("Excel.Application")
objExcel.DisplayAlerts = 0
objExcel.Workbooks.open excelPath, false, true

workSheetCount = objExcel.Worksheets.Count

WScript.Echo "We have " & workSheetCount & " worksheets"

For counter = 1 to workSheetCount
WScript.Echo "-----------------------------------------------"
WScript.Echo "Reading data from worksheet " & counter & vbCRLF

Set currentWorkSheet = objExcel.ActiveWorkbook.Worksheets(counter)

usedRowsCount = currentWorkSheet.UsedRange.Rows.Count
top = currentWorksheet.UsedRange.Row

Set Cells = currentWorksheet.Cells
For row = 0 to (usedRowsCount-1)
    curRow = row+top
    word = Cells(curRow).Value
    WScript.Echo (word)
Next
Next

Set currentWorkSheet = Nothing
objExcel.Workbooks(1).Close
objExcel.Quit
Set currentWorkSheet = Nothing
Set objExcel = Nothing

Answer 1

Ммм ...

filename = "C:\Test\test.csv"

Set fso = CreateObject("Scripting.FileSystemObject")
Set f   = fso.OpenTextFile(filename)

Do Until f.AtEndOfStream
    line = f.ReadLine
Loop

f.Close

WScript.Echo line

CSV - это текстовый формат, поэтому вы можете легко обработать его с помощью FileSystemObject методов без использования Excel.