Преобразование XML с несколькими выходами с использованием XSLT в XML с одним выходом - PullRequest
Новая
       4

Преобразование XML с несколькими выходами с использованием XSLT в XML с одним выходом

0 голосов
/ 28 января 2019

Я пытаюсь преобразовать (сгладить) XML с несколькими выходами, используя XSLT, в XML с одним выходом.Но узел, который должен быть продублирован для каждого узла, игнорируется.XML-файл имеет два выхода: HEAD и EXPERIMENT.

Исходный XML-документ: 

<?xml version="1.0" encoding="utf-8"?>
<ELEMENT>
    <HEAD>
        <FIRSTNAME>Anton</FIRSTNAME>
        <SURNAME>Konchik</SURNAME>
        <REPORTDATE>01.01.2019</REPORTDATE>
    </HEAD>
    <EXPERIMENT>
        <NAME>EXPERIMENT1</NAME>
        <DATE>01.01.2018</DATE>
        <RESULT>POSITIVE</RESULT>
    </EXPERIMENT>
    <EXPERIMENT>
        <NAME>EXPERIMENT2</NAME>
        <DATE>01.01.2019</DATE>
        <RESULT>NEGATIVE</RESULT>
    </EXPERIMENT>
    <EXPERIMENT>
        <NAME>EXPERIMENT3</NAME>
        <DATE>01.01.2017</DATE>
        <RESULT>NOTSURE</RESULT>
    </EXPERIMENT>
</ELEMENT>

Используя приведенный ниже код, я хочу продублировать узел HEAD внутри каждого узла EXPERIMENT.Код XSLT-преобразования: 

<?xml version='1.0' ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" version="2.0" encoding="UTF-8" />
    <xsl:template match="/">
        <xsl:element name="ELEMENT">
            <xsl:for-each select="ELEMENT/EXPERIMENT">
                <xsl:element name="EXPERIMENT">

                    <xsl:element name="NAME">
                          <xsl:value-of select="./NAME"/>
                    </xsl:element>

                    <xsl:element name="DATE">
                          <xsl:value-of select="./DATE"/>
                    </xsl:element>

                    <xsl:element name="RESULT">
                          <xsl:value-of select="./RESULT"/>
                    </xsl:element>

                        <xsl:for-each select="ELEMENT/HEAD">
                           <xsl:element name="FIRSTNAME">
                                  <xsl:value-of select="./FIRSTNAME"/>
                            </xsl:element>
                           <xsl:element name="SURNAME">
                                  <xsl:value-of select="./SURNAME"/>
                            </xsl:element>
                           <xsl:element name="REPORTDATE">
                                  <xsl:value-of select="./REPORTDATE"/>
                            </xsl:element>
                        </xsl:for-each>

                </xsl:element>          
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

Исключительный результат: 

<?xml version="1.0" encoding="utf-8"?>
<ELEMENT>
    <EXPERIMENT>
        <NAME>EXPERIMENT1</NAME>
        <DATE>01.01.2018</DATE>
        <RESULT>POSITIVE</RESULT>
        <FIRSTNAME>Anton</FIRSTNAME>
        <SURNAME>Konchik</SURNAME>
        <REPORTDATE>01.01.2019</REPORTDATE>
    </EXPERIMENT>
    <EXPERIMENT>
        <NAME>EXPERIMENT2</NAME>
        <DATE>01.01.2019</DATE>
        <RESULT>NEGATIVE</RESULT>
        <FIRSTNAME>Anton</FIRSTNAME>
        <SURNAME>Konchik</SURNAME>
        <REPORTDATE>01.01.2019</REPORTDATE>
    </EXPERIMENT>
    <EXPERIMENT>
        <NAME>EXPERIMENT3</NAME>
        <DATE>01.01.2017</DATE>
        <RESULT>NOTSURE</RESULT>
        <FIRSTNAME>Anton</FIRSTNAME>
        <SURNAME>Konchik</SURNAME>
        <REPORTDATE>01.01.2019</REPORTDATE>
    </EXPERIMENT>
</ELEMENT>

Но узел HEAD игнорируется.Фактический результат: 

<?xml version="1.0" encoding="utf-8"?>
<ELEMENT>
  <EXPERIMENT>
    <NAME>EXPERIMENT1</NAME>
    <DATE>01.01.2018</DATE>
    <RESULT>POSITIVE</RESULT>
  </EXPERIMENT>
  <EXPERIMENT>
    <NAME>EXPERIMENT2</NAME>
    <DATE>01.01.2019</DATE>
    <RESULT>NEGATIVE</RESULT>
  </EXPERIMENT>
  <EXPERIMENT>
    <NAME>EXPERIMENT3</NAME>
    <DATE>01.01.2017</DATE>
    <RESULT>NOTSURE</RESULT>
  </EXPERIMENT>
</ELEMENT>

Спасибо за помощь.

1 Ответ

0 голосов
/ 28 января 2019

Изменить: 

<xsl:for-each select="ELEMENT/HEAD">

на: 

<xsl:for-each select="/ELEMENT/HEAD">

или: 

<xsl:for-each select="../HEAD">

То, что вы ищете, ELEMENT, который является ребенкомтекущий EXPERIMENT.Вам нужно начать с корня дерева или подняться вверх по иерархии.

Обратите внимание, что вы можете сделать просто: 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/ELEMENT">
    <xsl:copy>
        <xsl:for-each select="EXPERIMENT">
            <xsl:copy>
                <xsl:copy-of select="*"/>
                <xsl:copy-of select="../HEAD/*"/>
            </xsl:copy>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...