Примечание : этот ответ для ANTLR3 ! Если вы ищете пример ANTLR4 , то этот Q & A демонстрирует, как создать простой анализатор выражений и вычислитель с использованием ANTLR4 .
Сначала вы создаете грамматику. Ниже приведена небольшая грамматика, которую вы можете использовать для оценки выражений, построенных с использованием 4 основных математических операторов: +, -, * и /. Вы также можете группировать выражения, используя круглые скобки.
Обратите внимание, что эта грамматика является очень простой: она не обрабатывает унарные операторы (минус в: -1 + 9) или десятичные числа, такие как .99 (без начального числа), чтобы назвать только два недостатка. Это всего лишь пример, над которым вы можете работать сами.
Вот содержимое файла грамматики Exp.g :
grammar Exp;
/* This will be the entry point of our parser. */
eval
: additionExp
;
/* Addition and subtraction have the lowest precedence. */
additionExp
: multiplyExp
( '+' multiplyExp
| '-' multiplyExp
)*
;
/* Multiplication and division have a higher precedence. */
multiplyExp
: atomExp
( '*' atomExp
| '/' atomExp
)*
;
/* An expression atom is the smallest part of an expression: a number. Or
when we encounter parenthesis, we're making a recursive call back to the
rule 'additionExp'. As you can see, an 'atomExp' has the highest precedence. */
atomExp
: Number
| '(' additionExp ')'
;
/* A number: can be an integer value, or a decimal value */
Number
: ('0'..'9')+ ('.' ('0'..'9')+)?
;
/* We're going to ignore all white space characters */
WS
: (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
;
(правила синтаксического анализатора начинаются со строчной буквы, а правила лексера начинаются с заглавной буквы)
После создания грамматики вы захотите сгенерировать из нее парсер и лексер. Загрузите ANTLR jar и сохраните его в том же каталоге, что и ваш файл грамматики.
Выполните следующую команду в командной оболочке / командной строке:
java -cp antlr-3.2.jar org.antlr.Tool Exp.g
Оно не должно выдавать никаких сообщений об ошибках, и теперь должны генерироваться файлы ExpLexer.java , ExpParser.java и Exp.tokens .
Чтобы проверить, все ли работает правильно, создайте этот тестовый класс:
import org.antlr.runtime.*;
public class ANTLRDemo {
public static void main(String[] args) throws Exception {
ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
ExpLexer lexer = new ExpLexer(in);
CommonTokenStream tokens = new CommonTokenStream(lexer);
ExpParser parser = new ExpParser(tokens);
parser.eval();
}
}
и скомпилируйте его:
// *nix/MacOS
javac -cp .:antlr-3.2.jar ANTLRDemo.java
// Windows
javac -cp .;antlr-3.2.jar ANTLRDemo.java
и запустите его:
// *nix/MacOS
java -cp .:antlr-3.2.jar ANTLRDemo
// Windows
java -cp .;antlr-3.2.jar ANTLRDemo
Если все идет хорошо, на консоль ничего не выводится. Это означает, что парсер не нашел никакой ошибки. Когда вы измените "12*(5-6)" на "12*(5-6", а затем перекомпилируете и запустите его, должно быть напечатано следующее:
line 0:-1 mismatched input '<EOF>' expecting ')'
Хорошо, теперь мы хотим добавить немного кода Java в грамматику, чтобы парсер действительно делал что-то полезное. Добавление кода может быть сделано путем размещения { и } внутри вашей грамматики с некоторым простым Java-кодом внутри нее.
Но сначала: все правила синтаксического анализатора в файле грамматики должны возвращать примитивное двойное значение. Вы можете сделать это, добавив returns [double value] после каждого правила:
grammar Exp;
eval returns [double value]
: additionExp
;
additionExp returns [double value]
: multiplyExp
( '+' multiplyExp
| '-' multiplyExp
)*
;
// ...
, который нуждается в небольшом объяснении: каждое правило должно возвращать двойное значение. Теперь, чтобы «взаимодействовать» с возвращаемым значением double value (которое НЕ находится внутри простого блока кода Java {...}) изнутри блока кода, вам необходимо добавить знак доллара перед value:
grammar Exp;
/* This will be the entry point of our parser. */
eval returns [double value]
: additionExp { /* plain code block! */ System.out.println("value equals: "+$value); }
;
// ...
Вот грамматика, но теперь с добавленным кодом Java:
grammar Exp;
eval returns [double value]
: exp=additionExp {$value = $exp.value;}
;
additionExp returns [double value]
: m1=multiplyExp {$value = $m1.value;}
( '+' m2=multiplyExp {$value += $m2.value;}
| '-' m2=multiplyExp {$value -= $m2.value;}
)*
;
multiplyExp returns [double value]
: a1=atomExp {$value = $a1.value;}
( '*' a2=atomExp {$value *= $a2.value;}
| '/' a2=atomExp {$value /= $a2.value;}
)*
;
atomExp returns [double value]
: n=Number {$value = Double.parseDouble($n.text);}
| '(' exp=additionExp ')' {$value = $exp.value;}
;
Number
: ('0'..'9')+ ('.' ('0'..'9')+)?
;
WS
: (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
;
и так как наше правило eval теперь возвращает значение типа double, измените ваш ANTLRDemo.java на это:
import org.antlr.runtime.*;
public class ANTLRDemo {
public static void main(String[] args) throws Exception {
ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
ExpLexer lexer = new ExpLexer(in);
CommonTokenStream tokens = new CommonTokenStream(lexer);
ExpParser parser = new ExpParser(tokens);
System.out.println(parser.eval()); // print the value
}
}
Снова (пере) сгенерируйте свежий лексер и парсер из вашей грамматики (1), скомпилируйте все классы (2) и запустите ANTLRDemo (3):
// *nix/MacOS
java -cp antlr-3.2.jar org.antlr.Tool Exp.g // 1
javac -cp .:antlr-3.2.jar ANTLRDemo.java // 2
java -cp .:antlr-3.2.jar ANTLRDemo // 3
// Windows
java -cp antlr-3.2.jar org.antlr.Tool Exp.g // 1
javac -cp .;antlr-3.2.jar ANTLRDemo.java // 2
java -cp .;antlr-3.2.jar ANTLRDemo // 3
и теперь вы увидите результат выражения 12*(5-6), напечатанный на вашей консоли!
Опять же, это очень краткое объяснение. Я призываю вас просмотреть ANTLR wiki и прочитать некоторые учебные пособия и / или поиграть с тем, что я только что опубликовал.
Удачи!
EDIT:
В этом посте показано, как расширить приведенный выше пример, чтобы можно было предоставить Map<String, Double>, который содержит переменные в предоставленном выражении.
Чтобы этот код работал с текущей версией Antlr (июнь 2014 г.), мне нужно было внести несколько изменений. ANTLRStringStream необходимо, чтобы оно стало ANTLRInputStream, возвращаемое значение нужно было изменить с parser.eval() на parser.eval().value, и мне нужно было удалить предложение WS в конце, потому что значения атрибутов, такие как $channel, больше не являются разрешено появляться в действиях лексера.