Как переупорядочить гистограмму

Question

Я сгенерировал гистограмму для различных типов упражнений по статусу выхода на пенсию.Однако график упорядочен по статусу выхода на пенсию (выбыл или не вышел на пенсию)

Я хотел бы упорядочить график по типу упражнения, чтобы для каждого типа упражнения статус выхода на пенсию был сгруппирован вместе.

Пример использования игрушки Stata auto можно найти ниже:

sysuse auto, clear
graph bar turn mpg gear_ratio, over(foreign)

В этом примере я хотел бытип автомобиля, который нужно сгруппировать для каждого атрибута автомобиля.

Answer 1

Согласно предложению @ NickCox, можно также использовать команду , внесенную сообществом *1002* statplot.

Приведенный ниже код генерирует эквивалентный график в одну строку:

sysuse auto, clear 
statplot gear_ratio mpg turn, over(foreign) vertical asyvars

Для использования statplot сначала установите его с помощьювведите в командной строке Stata следующее:

ssc install statplot

Answer 2

Команда reshape - это хороший способ получить данные в нужном формате:

sysuse auto, clear

local my_yvars "turn mpg gear_ratio"
local my_cat_var "foreign"

/* Store variable labels to relabel the variables below */

local labels ""
foreach var of varlist `my_yvars' {
    local `var': variable label `var'
    local labels `"`labels' ("`var'" = "``var''")"'
}

collapse (mean) `my_yvars', by(`my_cat_var')
rename (`my_yvars') (y=)
reshape long y, i(`my_cat_var') j(variable) string

strrec variable `labels', replace
graph bar y , over(`my_cat_var') over(variable) asyvars

Обратите внимание, что strrec это команда сообщества , которую можно установить из SSC:

ssc install strrec