Как мне сбросить нумерацию в таблицах?

Question

У меня есть некоторые данные, с которыми я работал.После этого я удаляю записи на лету.Теперь, когда у меня есть рабочая модель данных, я хочу перезапустить свою автонумерацию.Как мне сбросить мои существующие данные, чтобы они соответствовали автоматическому форматированию, начиная с 1 .... n?

Я пытался сделать Compact and Repair, но это, похоже, не решило проблему.

Для справки моя таблица выглядит следующим образом:

R-002
R-054
R-123
R-057
R-061

Я хотел бы получить их обратно:

   R-001
   R-002
   R-003
   R-004
   R-005

И для каждой последующей добавленной записи придерживайтеськ этой новой автоматической нумерации, поэтому следующая запись, например, будет R-006.

Запись запроса UPDATE работает для немедленного исправления, но не учитывает соблюдение автоматической нумерации длябудущие записи.

Я думаю, есть элегантный способ сделать это.Данные в моих таблицах являются частью Relationships, поэтому это немного сложнее.

Если у кого-нибудь есть какие-либо советы / рекомендации, я был бы признателен.

Answer 1

Что вам нужно, это последовательная нумерация записей.

Я написал статью о различных методах для этого: Последовательные строки в Microsoft Access

Нужно добавить номера строк :

' Builds consecutive row numbers in a select, append, or create query
' with the option of a initial automatic reset.
' Optionally, a grouping key can be passed to reset the row count
' for every group key.
'
' 2018-08-23. Gustav Brock, Cactus Data ApS, CPH.
'
Public Function RowNumber( _
    ByVal Key As String, _
    Optional ByVal GroupKey As String, _
    Optional ByVal Reset As Boolean) _
    As Long

    ' Uncommon character string to assemble GroupKey and Key as a compound key.
    Const KeySeparator      As String = "¤§¤"
    ' Expected error codes to accept.
    Const CannotAddKey      As Long = 457
    Const CannotRemoveKey   As Long = 5

    Static Keys             As New Collection
    Static GroupKeys        As New Collection
    Dim Count               As Long
    Dim CompoundKey         As String

    On Error GoTo Err_RowNumber

    If Reset = True Then
        ' Erase the collection of keys and group key counts.
        Set Keys = Nothing
        Set GroupKeys = Nothing
    Else
        ' Create a compound key to uniquely identify GroupKey and its Key.
        ' Note: If GroupKey is not used, only one element will be added.
        CompoundKey = GroupKey & KeySeparator & Key
        Count = Keys(CompoundKey)

        If Count = 0 Then
            ' This record has not been enumerated.
            '
            ' Will either fail if the group key is new, leaving Count as zero,
            ' or retrieve the count of already enumerated records with this group key.
            Count = GroupKeys(GroupKey) + 1
            If Count > 0 Then
                ' The group key has been recorded.
                ' Remove it to allow it to be recreated holding the new count.
                GroupKeys.Remove (GroupKey)
            Else
                ' This record is the first having this group key.
                ' Thus, the count is 1.
                Count = 1
            End If
            ' (Re)create the group key item with the value of the count of keys.
            GroupKeys.Add Count, GroupKey
        End If
        ' Add the key and its enumeration.
        ' This will be:
        '   Using no group key: Relative to the full recordset.
        '   Using a group key:  Relative to the group key.
        ' Will fail if the key already has been created.
        Keys.Add Count, CompoundKey
    End If

    ' Return the key value as this is the row counter.
    RowNumber = Count

Exit_RowNumber:
    Exit Function

Err_RowNumber:
    Select Case Err
        Case CannotAddKey
            ' Key is present, thus cannot be added again.
            Resume Next
        Case CannotRemoveKey
            ' GroupKey is not present, thus cannot be removed.
            Resume Next
        Case Else
            ' Some other error. Ignore.
            Resume Exit_RowNumber
    End Select
End Function

Это можно форматировать по своему усмотрению, например:

RNumber: "R-" & Format([RwoNumber], "000")