Отдельный номер от текста - PullRequest
Новая
       8

Отдельный номер от текста

0 голосов
/ 21 сентября 2018

Я использую Excel 2010, и у меня в одной ячейке следующий текст: 

Hash Rates
44Th/s
485Mh/s
432Mh/s
7Th/s
365Mh/s
33Th/s
3.1Th/s
6Th/s
10Gh/s
240kh/s
24.5Th/s
160kh/s

Я хотел бы отделить число от текста.Например, для 44Th/s я хотел бы получить 44 и Th/s.

Я попытался создать вспомогательную ячейку иди получить положение числа и текста по следующей формуле: 

=MIN(FIND({0;1;2;3;4;5;6;7;8;9};E2&"0123456789"))

В результате я сейчас пытаюсь отделить текст от числа с помощью: 

=RIGHT(E2;LEN(E2)-L2+1)

Однако я получаю только первоначальный текст: 

Hash Rates
44Th/s
485Mh/s
432Mh/s

Любойпредложения, как отделить текст от числа?

Я ценю ваши ответы!

Ответы [ 2 ]

0 голосов
/ 21 сентября 2018

Попробуйте получить цифры: 

=LEFT(A2,AGGREGATE(14,6,ROW($A$1:INDEX(A:A,LEN(A2)))/(ISNUMBER(--MID(A2,ROW($A$1:INDEX(A:A,LEN(A2))),1))),1))

Затем получите текст: 

=SUBSTITUTE(A2,B2,"")

enter image description here

0 голосов
/ 21 сентября 2018

=MIN(FIND({0;1;2;3;4;5;6;7;8;9};E2&"0123456789")) возвращает 1, потому что все ваши данные начинаются с цифры.

Попробуйте вместо этого:

=SUMPRODUCT(--(MID(E2;ROW(INDIRECT("1:"&LEN(E2)));1)={"0";"1";"2";"3";"4";"5";"6";"7";"8";"9";"."}))

Это можно комбинировать сформула, так что идет к:

Номер части:

=--LEFT(E2;SUMPRODUCT(--(MID(E2;ROW(INDIRECT("1:"&LEN(E2)));1)={"0";"1";"2";"3";"4";"5";"6";"7";"8";"9";"."})))

Текстовая часть

=RIGHT(E2;LEN(E2)-SUMPRODUCT(--(MID(E2;ROW(INDIRECT("1:"&LEN(E2)));1)={"0";"1";"2";"3";"4";"5";"6";"7";"8";"9";"."})))

...