Загрузка файла с URL с помощью запуска Chrome

Question

У меня есть пакетный файл, который открывает URL для загрузки файла CSV, затем мне нужно переместить и затем переименовать эту папку загрузок формы CSV в другую.

Что у меня есть:

@echo off

SET CCDIR=C:\Users\(username)\Desktop
SET LOADDIR=C:\Users\(username)\Downloads

ECHO ***************************************************************************
ECHO  Downloading the file
ECHO ***************************************************************************

start chrome (URL string)

:NEXT

ECHO ***************************************************************************
ECHO  Move CSV file from Downloads folder to Desktop
ECHO ***************************************************************************

move %LOADDIR%\*(file string)* %CCDIR%
ren %CCDIR%\*(file string)* (new file name)

Я хочу выполнить все это в одной летучей мыши, но только стартовый хром работает, летучая мышь игнорирует ход и рен.

Как я могу это сделать?

Answer 1

Исходя из моего комментария, вы можете попробовать для этого примера загрузить файл с Certuil command

@echo off
Title Downloading a file using Certutil Command
Mode 70,5 & color 0A
SET CCDIR=%userprofile%\Desktop
SET LOADDIR=%userprofile%\Downloads
set "url=https://download.sysinternals.com/files/PSTools.zip"
echo(
ECHO   ******************************************************************
ECHO          Please wait a while ... Downloading the file ...
ECHO   ******************************************************************
Call :download %url% %LOADDIR%
Rem Moving the downloaded file from the folder Downloads to Desktop
move /Y "%file%" "%CCDIR%\">nul
Rem Open the desktop folder with explorer
Explorer "%CCDIR%\"
goto :eof
::--------------------------------------------
:Download <Url> <File>
Set url="%~1"
Set file=%2\%~nx1
certutil.exe -urlcache -split -f %url% %file%>nul
Rem Deleting cache
certutil -urlcache "%~1" delete>nul
Rem Check referenced urlcache is deleted
certutil.exe -v -urlcache -split "%~1">nul
exit /b
::--------------------------------------------