Интроспективные функции с пунктами охраны - PullRequest
Новая
       46

Интроспективные функции с пунктами охраны

0 голосов
/ 23 мая 2018

Учитывая модуль, имеющий две функции с одинаковой арностью, но разными защитными предложениями, как я (в идеале) вижу, что это за предложения, или, по крайней мере, существует две функции?

defmodule Test do
  def greet(name) when name == "foo" do
    IO.puts("Hello, bar")
  end

  def greet(name), do: IO.puts("Hello, #{name}")
end

Test.__info__(:functions) не работает, а только возвращает [greet: 1]

Ответы [ 2 ]

0 голосов
/ 23 мая 2018

Если модуль является сторонним и / или уже скомпилирован, обратитесь к ответу, предоставленному @ Dogbert.

Если модуль принадлежит, запрошенная информация может быть собрана на этапе компиляции с использованием @on_definition hook: 

defmodule TestInfo do
  def on_definition(_env, kind, name, args, guards, body) do
    with {:ok, table} <- :dets.open_file(:test_info, type: :set) do
      clauses =
        case :dets.lookup(table, name) do
          {:error, _reason} -> []
          [] -> []
          list when is_list(list) -> list[name]
        end

      :dets.insert(table, {name, [{kind, args, guards} | clauses]})
      :dets.close(table)
    end
  end
end

defmodule Test do
  @on_definition {TestInfo, :on_definition} # ⇐ THIS

  def greet(name) when name == "foo" do
    IO.puts("Hello, bar")
  end

  def greet(name), do: IO.puts("Hello, #{name}")
end

Теперь у вас есть все определения, сохраненные в DETS: 

{:ok, table} = :dets.open_file(:test_info, type: :set) 
:dets.lookup(table, :greet)
#⇒ [
#    greet: [
#      {:def, [{:name, [line: 10], nil}], []},
#      {:def, [{:name, [line: 6], nil}],
#       [{:==, [line: 6], [{:name, [line: 6], nil}, "foo"]}]}]
#  ]

:dets.close(table)

Я использовал DETS для хранения информации, потому что она хранится в этап компиляции и его типичное использование во время выполнения.

0 голосов
/ 23 мая 2018

Вы можете декомпилировать код модуля в «абстрактный код» и покопаться в нем, чтобы получить эту информацию.Вот как вы можете получить предложения для каждой функции в модуле: 

module = Test

{:ok, {^module, [abstract_code: {:raw_abstract_v1, abstract_code}]}} = :beam_lib.chunks(module, [:abstract_code])

for {:function, _, name, arity, clauses} <- abstract_code do
  # Uncomment the next line to print the AST of the clauses.
  # IO.inspect(clauses)
  IO.inspect {name, arity, length(clauses)}
end

Вывод: 

{:__info__, 1, 7}
{:greet, 1, 2}

Примечание. Вероятно, это частный API, который может измениться в будущих версиях Erlang/ OTP.Вывод выше на Erlang / OTP 20.

...