Удаление строк в VBA на основе списка

Question

В моих таблицах есть две вкладки (Отчет и Праздники).В столбце A вкладки «Праздники» есть список дат (обновляется вручную), которые я хочу исключить из вкладки «Отчет» (столбец E содержит даты).

Я нашел код, который делает то, что нужно, но требует некоторыхвремя, когда число строк составляет около 100-200k:

Sub Holidays()
Application.DisplayAlerts = False
Dim d As Object, e, rws&, cls&, i&, j&
Set d = CreateObject("scripting.dictionary")
For Each e In Sheets("Holidays").Range("A1").CurrentRegion
    d(e.Value) = 1
Next e
Sheets("Report").Activate
rws = Cells.Find("*", After:=[a1], SearchOrder:=xlByRows, _
        SearchDirection:=xlPrevious).Row
cls = Cells.Find("*", After:=[a1], SearchOrder:=xlByColumns, _
        SearchDirection:=xlPrevious).Column
For i = rws To 1 Step -1
    For j = 1 To cls
        If d(Range("A1").Resize(rws, cls)(i, j).Value) = 1 Then _
            Cells.Rows(i).Delete: Exit For
Next j, i
Application.DisplayAlerts = True
End Sub

Есть ли способ ускорить этот макрос?В идеале, запуск займет всего несколько секунд.

Заранее благодарю за помощь.

Answer 1

Это должно удалить около 10 K строк из 200 K, менее чем за 30 секунд

В приведенном ниже коде предполагается, что UsedRange на обоих листах начинается с A1 и

• Лист Holidays содержит только столбец A (в смежных строках)
• Лист Report содержит даты, подлежащие удалению в столбце E (в смежных строках)
• Даты воба листа имеют формат "m/d/yyyy"

---

Option Explicit

Public Sub RemoveHolidaysFromReportFilterUnion()
    Const WS_NAME = "Report"
    Dim wsH As Worksheet:   Set wsH = ThisWorkbook.Worksheets("Holidays")
    Dim wsR As Worksheet:   Set wsR = ThisWorkbook.Worksheets(WS_NAME)

    Dim del As Range, wsNew As Worksheet

    Application.ScreenUpdating = False
    Set del = GetRowsToDelete(wsH, wsR)
    If del.Cells.Count > 1 Then
        del.EntireRow.Hidden = True
        Set wsNew = ThisWorkbook.Worksheets.Add(After:=wsR)
        wsR.UsedRange.SpecialCells(xlCellTypeVisible).EntireRow.Copy
        With wsNew.Cells(1)
            .PasteSpecial xlPasteColumnWidths
            .PasteSpecial xlPasteAll
            .Select
        End With
        Application.DisplayAlerts = False
        wsR.Delete
        Application.DisplayAlerts = True
        wsNew.Name = WS_NAME
    End If
    Application.ScreenUpdating = True
End Sub

---

Private Function GetRowsToDelete(ByRef wsH As Worksheet, ByRef wsR As Worksheet) As Range
    Const HOLIDAYS_COL = "A"
    Const REPORT_COL = "E"
    Dim arr As Variant, i As Long, itm As Variant

    ReDim arr(1 To wsH.UsedRange.Rows.Count - 1)
    i = 1
    For Each itm In wsH.UsedRange.Columns(HOLIDAYS_COL).Offset(1).Cells
        If Len(itm) > 0 Then
            arr(i) = itm.Text   'Create AutoFilter Array (dates as strings)
            i = i + 1
        End If
    Next

    Dim ur As Range, del As Range, lr As Long, fc As Range

    With wsR.UsedRange
        Set ur = .Resize(.Rows.Count - 1, 1).Offset(1)
        Set del = wsR.Cells(.Rows.Count + 1, REPORT_COL)
    End With

    lr = wsR.UsedRange.Rows.Count
    Set fc = wsR.Range(wsR.Cells(1, REPORT_COL), wsR.Cells(lr, REPORT_COL))
    fc.AutoFilter Field:=1, Criteria1:=arr, Operator:=xlFilterValues
    If fc.SpecialCells(xlCellTypeVisible).Cells.Count > 1 Then
        Set del = Union(del, ur.SpecialCells(xlCellTypeVisible))
    End If
    fc.AutoFilter
    Set GetRowsToDelete = del
End Function

---

Производительность - Removed about 5K rows out of a total of 100K

Sheet Report   - Rows: 100,011, Cols: 11   (Rows Left: 94,805 - Deleted: 5,206)
Sheet Holidays - Rows:      20, Cols:  1

Initial Sub - Holidays()              - Time: 112.625 sec
RemoveHolidaysFromReportFilterUnion() - Time:  10.512 sec

---

Данные испытаний

Holidays

---

Report - Before

Report - After