Как установить цвет фона на строку? - PullRequest
Новая
       101

Как установить цвет фона на строку?

0 голосов
/ 24 сентября 2018

Я пытаюсь присвоить цвет фона элементу строки в моем приложении.Пока что я заархивировал это с прямоугольником, но он испортил изображения в MouseArea

Вот мой код: - 

import QtQuick.Controls  2.4
import QtQuick 2.11

ApplicationWindow {

        id:rootAppWin
        width:640
        height:480
        visible: true

        StackView {

                id: rooAppStack
                anchors.bottomMargin: 50
                anchors{
                        fill:parent
                }
        }

        //Bottom Buttons
        Row{

                Rectangle {
                        color: "#19d4d4d4"
                        anchors.fill:parent
                }

                id:rootNavButtons
                anchors{
                        top: rooAppStack.bottom
                        right: parent.right
                        bottom: parent.bottom
                        left: parent.left
                        topMargin: 5
                }

                MouseArea {
                        id:marootback
                        width: parent.width/2
                        height: parent.height
                        Image {
                                id: marootbackimg
                                fillMode: Image.PreserveAspectFit
                                source: "qrc:/img/sideswipe.svg"
                                anchors.fill:parent
                        }
                }

                MouseArea {
                        id:maroothome
                        width: parent.width/2
                        height: parent.height
                        Image {
                                id: maroothomeimg
                                fillMode: Image.PreserveAspectFit
                                source: "qrc:/img/tent.svg"
                                anchors.fill:parent
                        }
                }


        }
}

Это испортило изображения: -

enter image description here

Без прямоугольника это прекрасно работает, но я не могу установить цвет фона.Что мне делать?

1 Ответ

0 голосов
/ 24 сентября 2018

Положить Строка в прямоугольнике 

    Rectangle {
            color: "#19d4d4d4"
            anchors{
                    top: rooAppStack.bottom
                    right: parent.right
                    bottom: parent.bottom
                    left: parent.left
                    topMargin: 5
            }
            Row{
                    anchors.fill:parent
                    id:rootNavButtons
                    MouseArea {
                            id:marootback
                            width: parent.width/2
                            height: parent.height
                            Image {
                                    id: marootbackimg
                                    fillMode: Image.PreserveAspectFit
                                    source: "qrc:/img/sideswipe.svg"
                                    anchors.fill:parent
                            }
                    }

                    MouseArea {
                            id:maroothome
                            width: parent.width/2
                            height: parent.height
                            Image {
                                    id: maroothomeimg
                                    fillMode: Image.PreserveAspectFit
                                    source: "qrc:/img/tent.svg"
                                    anchors.fill:parent
                            }
                    }

            }

    }
...