SUMIFS для суммирования данных между пользовательским диапазоном дат

Question

Я строю приборную панель для обобщения данных о покупке.У меня есть рабочий лист для данных о покупке, есть рабочий лист справочных таблиц с датами начала и окончания для финансовых месяцев, с соответствующим финансовым годом и финансовым месяцем (суммированы ниже), а также рабочий лист панели мониторинга.

Таблица: oetFiscalMonths

Start Date | End Date | Month    | Year  
10/1/17    | 10/30/17 | October  | 2018  
10/31/17   | 11/1/17  | November | 2018  

На панели инструментов есть таблица данных, отформатированная как показано ниже

         | Beginning Budget | Total Purchases | Remaining Budget |  
October  | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  
November | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  
December | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  
January  | $XXXXXXXXX.00    | $XXXXXX.00      | $XXXXXXXXXX.00   |  

Формула, которую я хочу ввести, будет идтив общей сумме покупок и суммирует все покупки, сделанные в финансовом месяце справа, на основе таблицы за финансовые месяцы, а также отвечает ряду других критериев, которые я смог выполнить по формуле SUMIFS.Я просто не уверен, как обращаться с частью диапазона дат, поскольку они не следуют за календарными месяцами даже в основном удаленно, и таблица для дат отформатирована так, как она есть, поскольку некоторые другие части используют ее текущий формат.

Любая помощь очень ценится!

Answer 1

Вы можете попробовать также по формуле sumproduct, ее преимущество без расчета формулы открытого листа.

=SUMPRODUCT(--(B:B>=H3)*(B:B<=I3),(C:C))

C: C = диапазон сумм

B: B =Диапазон поиска даты

H3 = Значение даты начала

I3 = Значение даты окончания

Answer 2

Предполагая, что sheet1 является вашей приборной панелью, sheet2 содержит вашу таблицу oetFiscalMonths, а sheet3 содержит покупки и соответствующие им даты покупки, которые вы хотите SUM, вы можете использовать SUMIFS в сочетании сINDEX + MATCH для соответствия вашей текущей файловой структуре:

=SUMIFS(sheet3!C:C,sheet3!B:B,">="&INDEX(sheet2!A:A,MATCH(sheet1!A2,sheet2!C:C,0)),sheet3!B:B,"<="&INDEX(sheet2!B:B,MATCH(sheet1!A2,sheet2!C:C,0)))

Легенды следующие:

sheet3!C:C содержит значения покупки, которые вы хотите SUM

sheet3!B:B содержит дату покупки

sheet2!A:A содержит даты начала ваших месяцев

sheet2!B:B содержит даты окончания ваших месяцев

sheet2!C:C содержит вашимесяцы

sheet1!A2 содержит первый месяц, в который вы хотите получить SUM покупок.

Answer 3

Вы можете использовать SUMIFS, как я показал ниже.Извините за случайное использование строки и ячейки.Я попытаюсь объяснить ниже.

=SUMIFS(C:C,A:A,">="&G1,A:A,"<="&H1)

C: C = диапазон суммы
A: A = диапазон поиска даты
G1 = значение даты начала
H1 = значение даты окончания

РЕДАКТИРОВАТЬ: Я бы предложил переместить столбец месяцев вперед, а затем даты после, как показано ниже.Таким образом, вы можете использовать vlookup, чтобы найти дату, а затем включить vlookup в sumifs.

  Month  | Start Date | End Date | Year  
October  | 10/1/17    | 10/30/17 | 2018  
November | 10/31/17   | 11/1/17  | 2018

=SUMIFS(G:G,F:F,">="&VLOOKUP(J6,M:O,2,0),F:F,"<="&VLOOKUP(J6,M:O,3,0))

M: O - это таблица вашего финансового года
J6это место, где вы вводите месяц, который вы ищете
Столбец 2 в первом VLOOKUP даст вам дату начала
Столбец 3 во втором VLOOKUP даст вам дату окончания


Позвольте мнезнать, если у вас есть какие-либо вопросы, это может быть немного запутанным, так как я использую случайные строки и столбцы.