Проблема с запуском функции Loop в Excel

Question

Я получил этот код, но он, кажется, не работает до конца.Застревает и отладчик просто выделяет ключевое слово Loop или строку i = i + 1.Что я делаю неправильно?

Я пытался If оператор или For … Next, но, похоже, ничего не работает.

Sub Macro1()
    '
    ' Macro1 Macro
    '
    Dim i As Integer    
    i = 2

    Do Until i > 586
        Range("B2").Formula = "=sheet2!CS" & i & ""
        Range("B3").Formula = "=sheet2!CR" & i & ""
        Range("B4").Formula = "=sheet2!CQ" & i & ""
        Range("B5").Formula = "=sheet2!CP" & i & ""
        Range("B6").Formula = "=sheet2!CO" & i & ""
        Range("B7").Formula = "=sheet2!CN" & i & ""
        Range("B8").Formula = "=sheet2!CM" & i & ""
        Range("B9").Formula = "=sheet2!CL" & i & ""
        Range("B10").Formula = "=sheet2!CK" & i & ""
        Range("B11").Formula = "=sheet2!CJ" & i & ""
        Range("B12").Formula = "=sheet2!CI" & i & ""
        Range("B13").Formula = "=sheet2!CH" & i & ""
        Range("B14").Formula = "=sheet2!CG" & i & ""

        'Copy and PasteSpecial a Range
        Range("AL18").Copy
        Worksheets("Sheet2").Range("CV" & i & "").PasteSpecial Paste:=xlPasteValues

        i = i + 1
    Loop
End Sub

Answer 1

Простая медленная версия

Sub LoopTrouble()
  Dim i As Integer
  Dim j As Integer
    For i = 2 To 586
      For j = 1 To 13
        Sheet1.Cells(j + 1, 2) = Sheet2.Cells(i, 98 - j)
'        Sheet1.Cells(j + 1, "B") = Sheet2.Cells(i, 98 - j)
'        Sheet1.Range("B" & j + 1) = Sheet2.Cells(i, 98 - j)
      Next
      Sheet2.Cells(i, 100) = Sheet1.Cells(18, 38)
    Next
End Sub

Быстрее 'Semi' Array Version

Sub LoopTroubleFaster()
  Dim i As Integer
  Dim j As Integer
  Dim vntLT As Variant
  Dim vntPaste As Variant
    vntLT = Sheet2.Range(Cells(2, 85), Cells(586, 97)).Value2
    ReDim vntPaste(1 To 13, 1 To 1)
    For i = 1 To 585
      For j = 1 To 13
        vntPaste(j, 1) = vntLT(i, j)
      Next
      Sheet1.Range("B2:B14") = vntPaste
      Sheet2.Cells(i + 1, 100) = Sheet1.Cells(18, 38)
    Next
End Sub

Answer 2

Похоже, что при тестировании кода не было проблем с кодом.

Вот ваш код, хотя и сокращенный, и посмотрите, работает ли он.

Sub Macro1()
    Dim i As Long, j As Long
    Dim colltr As String

    For i = 2 To 586
        For j = 2 To 14
            colltr = Split(Cells(1, 99 - j).Address, "$")(1)
            Range("B" & j).Formula = "=sheet2!" & colltr & i
        Next j
    'Copy and PasteSpecial a Range

    Worksheets("Sheet2").Range("CV" & i & "").value = Range("AL18").value
    Next i

End Sub