Как обработать список имен файлов / папок в цикле FOR, который может содержать также восклицательный знак?

Question

Я пишу пакетный скрипт для поиска содержимого файла в папке.Содержимое находится в текстовом файле и содержит специальные символы, такие как восклицательный знак.

Как получить FILENAME и FOLDERNAME, которые содержат восклицательный знак.

@ECHO off
SETLOCAL EnableDelayedExpansion

set /p SRC="Enter source folder link: "
set /p DST="Enter destination folder link: "

FOR /F "delims=" %%a IN ('DIR /b /s /a-d "%SRC%"') do (
    Set "CODE=%%~na"
    Set "EXT=%%~xa"
    findstr /c:"!CODE!" "%SRC%\Content.txt">nul
    IF "!errorlevel!" EQU "0" (
        for /F "tokens=2,3" %%c in ('findstr /c:"!CODE!" "%SRC%\Content.txt"') do (
            ECHO !CODE!
            Set "NEWNAME=%%c"
            Set "FOLDERNAME=%%d"
            Set "NEWNAME=!NEWNAME:_= !"
            Set "FOLDERNAME=!FOLDERNAME:_= !"
            IF not exist "%DST%\!FOLDERNAME!" md "%DST%\!FOLDERNAME!"
            mklink "%DST%\!FOLDERNAME!\!NEWNAME!!EXT!" "%%a"
        )
    )
)
Endlocal
Exit

PS: в исходной папке много файлов.

Answer 1

Я не изучал ваш код, но я бы предположил, что включение отложенного расширения после задания имен переменных будет более уместным:

@Echo Off
SetLocal DisableDelayedExpansion

Set /P "SRC=Enter source folder link: "
Set /P "DST=Enter destination folder link: "

For /D /R %%A In (*) Do For /F "Tokens=2-3" %%B In (
    'FindStr/C:"%%~nxA" "%SRC%\Content.txt" 2^>Nul') Do (Echo %%~nA
    Set "NEW=%%B"
    Set "FLD=%%C"
    SetLocal EnableDelayedExpansion
    If Not Exist "%DST%\!FLD:_= !\" MD "%DST%\!FLD:_= !" 2>Nul && (
        MkLink "%DST%\!FLD:_= !\!NEW:_= !%%~xA" "%%A")
    Endlocal)
Exit /B

Я настоятельно рекомендую вам выполнить некоторые правильные действия.проверка пользовательского ввода перед выполнением задач с их использованием, т. е. перед циклом For.

Answer 2

Одним из решений является использование подпрограммы, чтобы избежать использования отложенного расширения переменной среды:

@echo off
setlocal EnableExtensions DisableDelayedExpansion

:GetSource
set "SRC="
set /P SRC="Enter source folder link: "
if not defined SRC goto GetSource
set "SRC=%SRC:"=%"
if not defined SRC goto GetSource

:GetDestination
set "DST="
set /P DST="Enter destination folder link: "
if not defined DST goto GetDestination
set "DST=%DST:"=%"
if not defined DST goto GetDestination

for /F "eol=| delims=" %%I in ('dir /A-D /B /S "%SRC%" 2^>nul') do (
    if exist "%SRC%\Content.txt" for /F "tokens=2,3" %%A in ('%SystemRoot%\System32\findstr.exe /C:"%%~nI" "%SRC%\Content.txt" 2^>nul') do (
        set "NEWNAME=%%~A"
        set "FOLDERNAME=%%~B"
        call :MakeLink "%%I"
    )
)

endlocal
exit /B

:MakeLink
echo %~n1
set "NEWNAME=%NEWNAME:_= %"
set "FOLDERNAME=%FOLDERNAME:_= %"
if not exist "%DST%\%FOLDERNAME%" md "%DST%\%FOLDERNAME%"
mklink "%DST%\%FOLDERNAME%\%NEWNAME%%~x1" %1
goto :EOF

Откройте окно командной строки и запустите call /?, чтобы объяснить, как использовать команду CALL с включенными расширениями команд для запуска блока в том же пакетном файле, что и подпрограмма.См. Также Куда возвращается GOTO: EOF?