XSLT для преобразования списка в таблицу с динамически определяемыми столбцами - PullRequest
Новая
       12

XSLT для преобразования списка в таблицу с динамически определяемыми столбцами

0 голосов
/ 28 октября 2009

Мне нужен этот XML, 

<list columns="3">
  <item>martin</item>
  <item>donald</item>
  <item>whistler</item>
  <item>mother</item>
  <item>carl</item>
  <item>liz</item>
  <item>cosmo</item>
</list>

чтобы выглядеть так: 

<table>
  <tr>
    <td>martin</td>
    <td>donald</td>
    <td>whistler</td>
  </tr>
  <tr>
    <td>mother</td>
    <td>carl</td>
    <td>liz</td>
  </tr>
  <tr>
    <td>cosmo</td>
    <td></td>
    <td></td>
  </tr>
</table>

Когда columns="4", это должно выглядеть так: 

<table>
  <tr>
    <td>martin</td>
    <td>donald</td>
    <td>whistler</td>
    <td>mother</td>
  </tr>
  <tr>
    <td>carl</td>
    <td>liz</td>
    <td>cosmo</td>
    <td></td>
  </tr>
</table>

Любые подсказки о том, как должен выглядеть XSLT-файл? Насколько я могу судить, это требует некоторого цикла (рекурсии?), Но я не уверен, что есть более элегантный способ.

Ответы [ 3 ]

8 голосов
/ 28 октября 2009

Подход, который я выбрал бы, заключается в сопоставлении элементов на 1-й, 4-й, 7-й позициях с использованием функции 'mod' для позиции () каждого элемента.

После сопоставления каждого такого элемента просто выполните цикл по следующим братьям и сестрам на основе количества столбцов.

Для последней строки, где может быть недостаточно элементов для завершения строки, существует рекурсивный шаблон для добавления в пустые ячейки в зависимости от количества элементов в последней строке. 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

   <!-- Global variable to get column count -->
   <xsl:variable name="columns" select="number(/list/@columns)"/>

   <!-- Match the root node -->
   <xsl:template match="list">
      <table>
         <!-- Match items in the 1st, 4th, 7th positions, etc (or whatever the column variable holds) -->
         <xsl:apply-templates select="item[position() mod $columns = 1]"/>
      </table>
   </xsl:template>

   <xsl:template match="item">
      <tr>
         <!-- Output the current item -->
         <td>
            <xsl:value-of select="."/>
         </td>
         <!-- Output the following items based on the number of required columns -->
         <xsl:for-each select="following-sibling::item[position() &lt; $columns]">
            <td>
               <xsl:value-of select="."/>
            </td>
         </xsl:for-each>
         <!-- Add in any empty cells if numberof following items is not sufficient -->
         <xsl:call-template name="emptycell">
            <xsl:with-param name="cellcounter" select="count(following-sibling::item[position() &lt; $columns]) + 1" />
         </xsl:call-template>
      </tr>
   </xsl:template>

   <!-- Recursive template to add in empty cells when there are not enough items to complete a row -->
   <xsl:template name="emptycell">
      <xsl:param name="cellcounter" />
      <xsl:if test="$cellcounter &lt; $columns">
         <td></td>
         <xsl:call-template name="emptycell">
            <xsl:with-param name="cellcounter" select="$cellcounter + 1" />
         </xsl:call-template>
      </xsl:if>   
   </xsl:template>

</xsl:stylesheet>
0 голосов
/ 28 октября 2009

Я предлагаю использовать CSS3 столбцы . Спецификация довольно скоро станет Рекомендацией кандидата (этап вызова) и уже реализована в Gecko и WebKit (Firefox, Safari, Chrome) с префиксами поставщиков.

Код: 

ul { -moz-column-count: 3; -webkit-column-count: 3; }
0 голосов
/ 28 октября 2009

Что-то, что работает, но выглядит немного уродливо: злоупотребление положением (). 

<xsl:param name="columns">4</xsl:param>
<xsl:template match="list">
  <xsl:variable name="theList" select="."/>
  <xsl:for-each select="//*[position()<(count(item) / $columns)]>
    <xsl:variable name="idx" select="position()"/>
    <tr>
    <xsl:for-each select="//*[position()<$columns]">
       <td><xsl:value-of select="$theList/item[position() + $idx * $columns]"/></td>
    </xsl:for-each>
    </tr>
  </xsl:for-each>
</xsl:template>

Существуют и другие способы: например, сначала выбрать все те узлы, которые делятся с остальными 0 столбцами в списке, а затем пройти по ним.

См. http://www.ibm.com/developerworks/library/x-tipnodst.html для более подробного описания техники выше.

...