Сделайте строку в SAS из одного столбца

Question

У меня есть набор данных в SAS, и я хочу преобразовать один столбец в строку с помощью продукта.Я приложил изображение ввода и вывода требуется.Мне нужно String Colomn в выходной.Может кто-нибудь, пожалуйста, помогите мне?

введите описание изображения здесь

Answer 1

Вот мое быстрое решение.

data temp;
  length cat $20.;
  do until (last.prod);
    set have;
    by prod notsorted;
   cat=catx(',',cat,value);
  end;

  drop value date;
run;

proc sql;
  create table want as
  select have.*, cat as string
  from have inner join temp
  on have.prod=temp.prod;
quit;

Answer 2

Я кодировал шаг данных для создания входных данных:

data have;
   input products $
         dates
         value
   ;

   datalines;
a 1 0
a 2 0
a 3 1
a 4 0
a 5 1
a 6 1
b 1 0
b 2 1
b 3 1
b 4 1
b 5 0
b 6 0
c 1 1
c 2 0
c 3 1
c 4 1
c 5 0
c 6 1
;

Дает ли следующее предлагаемое решение то, что вы хотите?:

data want;
   length string $ 20;

   do until(last.products);
      set have;
      by products;

      string = catx(',',string,value);
   end;

   do until(last.products);
      set have;
      by products;

      output;
   end;
run;