Как я могу перебрать список в пакетном режиме?

Question

У меня есть две строки:

jobID: w,x,y,z
Test: A,B,C,D

Я перебираю вторую строку (после разделения ее запятой) и печатаю как значение этого сгенерированного списка, так и значение из первой строки.

Мой код до сих пор такой:

@echo off
setlocal EnableDelayedExpansion

set num=-1
for %%a in ("%jobID:,=" "%") do (
   set /A num+=1
   set elem[!num!]=%%a
)

set i=-1
for %%a in ("%Test:,=" "%") do (
   set /A i=i+1
   echo file name is %%a and first list element is !%elem[!%i%!]%!
)

Что я ожидаю, это:

file name is A and first list element is w
file name is B and first list element is x
file name is C and first list element is y
file name is D and first list element is z

Что я получу:

file name is "A" and first list element is "0"
file name is "B" and first list element is "1"
file name is "C" and first list element is "2"
file name is "D" and first list element is "3"

РЕДАКТИРОВАТЬ: Мне нужно получить значения без двойных кавычек.

Answer 1

Вам необходимо получить две фазы расширения переменной.Это достигается с помощью команды CALL.

Измените свою команду echo на эту.

call echo file name is %%a and first list element is %%elem[!i!]%%

Все это объяснено в Массивы, связанные списки и другие структуры данных в cmd.Сценарий exe (пакетный)

Кавычки удаляются из переменной FOR с помощью модификаторов команд, которые описаны в последнем разделе справочного файла для команды FOR.

You can now use the following optional syntax:

    %~I         - expands %I removing any surrounding quotes (")
    %~fI        - expands %I to a fully qualified path name
    %~dI        - expands %I to a drive letter only
    %~pI        - expands %I to a path only
    %~nI        - expands %I to a file name only
    %~xI        - expands %I to a file extension only
    %~sI        - expanded path contains short names only
    %~aI        - expands %I to file attributes of file
    %~tI        - expands %I to date/time of file
    %~zI        - expands %I to size of file
    %~$PATH:I   - searches the directories listed in the PATH
                   environment variable and expands %I to the
                   fully qualified name of the first one found.
                   If the environment variable name is not
                   defined or the file is not found by the
                   search, then this modifier expands to the
                   empty string

The modifiers can be combined to get compound results:

    %~dpI       - expands %I to a drive letter and path only
    %~nxI       - expands %I to a file name and extension only
    %~fsI       - expands %I to a full path name with short names only
    %~dp$PATH:I - searches the directories listed in the PATH
                   environment variable for %I and expands to the
                   drive letter and path of the first one found.
    %~ftzaI     - expands %I to a DIR like output line