xslt удалить все атрибуты из xml

Question

У меня ниже образец xml

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<type>
<subtype id="1">
    <Shoebox>
        <author index="0">BUILTIN\Administrators</author>
        <dateModified index="0">2001-02-23T11:30:38.000
        </dateModified>
        <title index="0">false</title>
        <sourceLocation index="0">\\vms2\TestData\Filesystem\1 
                     doc
        </sourceLocation>
        <keywords index="0">doc1</keywords>
        <contentSize index="0">123</contentSize>
        <department index="0">Windows 7</department>
        <fileName index="0">doc1.docx</fileName>
        <dateCreated index="0">2001-02- 
23T11:30:38.000</dateCreated>
        <format index="0">docx</format>
    </Shoebox>      
</subtype>  
</type>    

и ниже мой xslt

 <?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet version="1.0" xmlns="urn:philips:en:xsd:Trailbalance.1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes" omit-xml-declaration="no"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="node()">
        <xsl:copy>
      <xsl:apply-templates />
    </xsl:copy>
    </xsl:template>
    <xsl:template match="type">
        <xsl:element name="trackwise">
            <xsl:apply-templates select="subtype"/>
        </xsl:element>  
    </xsl:template>
        <xsl:template match="subtype">      
        <xsl:for-each select="Shoebox">      
        <capa>      
          <xsl:copy-of select="node()" />
        </capa>
        </xsl:for-each>
        </xsl:template>

Ожидаемый xml такой же, как и ниже

<?xml version="1.0" encoding="UTF-8"?>
<trackwise>
<capa>
<author>BUILTIN\Administrators</author>
<dateModified>2001-02-23T11:30:38.000           </dateModified>
  <title>false</title>
<sourceLocation>\\vms2\TestData\Filesystem\1 doc    </sourceLocation>
<keywords>doc1</keywords>
<contentSize >123</contentSize>
<department>Windows 7</department>
<fileName>doc1.docx</fileName>
<dateCreated >2001-02-23T11:30:38.000</dateCreated>
<format>docx</format>
</capa>
</trackwise>

проблема свыше xslt это атрибуты "index" также скопированы, я хочу удалить атрибуты "index" из всех дочерних узлов, что я делаю неправильно в вышеупомянутом xslt.

Answer 1

сначала создайте шаблон удостоверения:

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

Если вы хотите удалить все атрибуты @index, вы также можете использовать

<xsl:template match="@index"/>

, вместо каждого для васможно использовать прямые совпадения шаблонов для достижения желаемых результатов

<xsl:template match="type">
    <trackwise>
        <xsl:apply-templates/>
    </trackwise>
</xsl:template>

<xsl:template match="Shoebox">
    <capa>
        <xsl:apply-templates/>
    </capa>
</xsl:template>

<xsl:template match="subtype">
    <xsl:apply-templates/>
</xsl:template>

Вся таблица стилей выглядит следующим образом:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@index"/>

    <xsl:template match="type">
        <trackwise>
            <xsl:apply-templates/>
        </trackwise>
    </xsl:template>

    <xsl:template match="Shoebox">
        <capa>
            <xsl:apply-templates/>
        </capa>
    </xsl:template>

    <xsl:template match="subtype">
        <xsl:apply-templates/>
    </xsl:template>

</xsl:stylesheet>

Answer 2

Если вы хотите удалить все атрибуты, используйте:

<xsl:template match="node()">
    <xsl:copy>
        <xsl:apply-templates select="node()"/>
    </xsl:copy>
</xsl:template>

См. Ссылку: http://xsltransform.net/nbiCsYY

И

Если вы хотитечтобы удалить все атрибуты index, используйте:

 <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@index"/>

См. ссылку: http://xsltransform.net/nbiCsYY/2

Answer 3

<capa>      
<xsl:apply-templates select="node()"/>
</capa>
use apply-template instead of copy-of element