Передача объекта функции и вызов его

Question

Как передать функцию a в функцию b и получить b вызов a в Perl?

Answer 1

Вот полный рабочий скрипт, который демонстрирует, что вы спрашиваете.

sub a { print "Hello World!\n"; }

sub b {
    my $func = $_[0];
    $func->();
}

b(\&a);

Вот объяснение: вы берете ссылку на функцию a, говоря \&a. В этот момент у вас есть ссылка на функцию; в то время как обычно функция вызывается с помощью func(), вы вызываете ссылку на функцию с помощью $func->()

Синтаксис -> относится и к другим ссылкам. Например, вот пример работы с ссылками на массив и хэш:

sub f {
    my ($aref, $href) = @_;
    print "Here's an array reference: $aref->[0]\n";  # prints 5
    print "Here's a hash ref: $href->{hello}\n";      # prints "world"
}

my @a = (5, 6, 7);
my %h = (hello=>"world", goodbye=>"girl");
f(\@a, \%h);

Answer 2

Вы не можете передать функцию другой функции напрямую. Вместо этого вы передаете ссылку в функцию. Чтобы вызвать функцию, вы разыменовываете ее (как код CODE), используя ->();

sub a { print @_ }

sub b {
  my $f = shift;  # assuming that $f is a function reference...
  $f->(@_);       # call it with the remaining arguments
}

b(\&a, "hello, world!");  # prints "hello, world!"

Perl не имеет семантики передачи по имени, но вы можете эмулировать их, используя хэш. Метод вызова функции такой же. Вы разыменовываете это.

sub a { print @_ }

sub b {
    my %arg = @_;
    $arg{function}->(@{$arg{arguments}});
}

b(function => \&a, arguments => ["hello, world!"]);

ObPerl6: Perl 6 будет иметь семантику передачи по имени.

Answer 3

Вы можете получить доступ к ссылкам подпрограмм как \&my_method в Perl и вызывать эти ссылки с помощью $myref->();. Попробуйте это:

perl -e'sub a { print "foo in a"; }; sub b { shift->(); }; b(\&a);'

Удачи!

Answer 4

Следуя примеру Эли Кортрайта: если вы используете первую функцию только один раз, вы можете также вызвать b с анонимной функцией, например:

b( sub { print "Hello World\n"; } );