Невозможно сгенерировать значение ширины Td, когда происходит colspan. В xslt встречается неправильная ширина

Question

У меня есть таблица и colgroup, я беру таблицу td width формы colgroup, которые упомянуты сверху в таблице.

Мне нужно определить ширину td, которая является конкретной colgroup.Например: для 2-го тд в таблице ширина берется из 2-й группы.

Работает нормально.но когда colspan встречается в td, он принимает только значение ширины col позиции.Я хочу, чтобы при появлении colspan он занимал всю предыдущую сумму col в ширине td.

Ввод

<?xml version="1.0" encoding="UTF-8"?>
<table size="s" orient="portrait" tablebodyrowalign="top" width="100">
  <colgroup>
    <col width="19%"/>
    <col width="6%"/>
    <col width="4%"/>
    <col width="9%"/>
    <col width="8%"/>
    <col width="3%"/>
    <col width="16%"/>
    <col width="4%"/>
    <col width="15%"/>
    <col width="2%"/>
    <col width="14%"/>
  </colgroup>
  <thead/>
  <tbody>
    <tr>
      <td colspan="5" align="center" valign="middle" fill="000080">
        <para style="TableBodyNoIndent">
          <emph type="Bold">Escrows and Reserves</emph>
          <emph type="Bold">
            <sup>(8)</sup>
          </emph>
        </para>
      </td>
      <td left="single" right="single" align="left" valign="top">
        <para style="TableBodyNoIndent"/>
      </td>
      <td colspan="5" left="single" top="single" right="single" bottom="single"
        align="center" valign="middle" fill="000080">
        <para style="TableBodyNoIndent">
          <emph type="Bold">Financial Information</emph>
          <emph type="Bold">
            <sup>(3)</sup>
          </emph>
        </para>
      </td>
    </tr>
  </tbody>
</table>

XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="2.0">
    <xsl:output method="xml" indent="yes"/>
   <xsl:strip-space elements="*"/>
   <xsl:template match="@*|node()">
       <xsl:copy>
           <xsl:apply-templates select="@*|node()"/>
       </xsl:copy>
   </xsl:template>
    <xsl:template match="table">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="tr">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="td">
        <xsl:copy>
        <xsl:attribute name="style">
            <xsl:variable name="pos">
                <xsl:number/>    
            </xsl:variable>

            <xsl:choose>
                <xsl:when test="preceding-sibling::td[@colspan]">
                    <xsl:if test="@fill">
                        <xsl:value-of select="concat('background-color: ','#',@fill, ';')"/>
                    </xsl:if>
                    <xsl:if test="@align">
                        <xsl:value-of select="concat('text-align:',@align,';')"/>
                    </xsl:if>
                    <xsl:value-of select="concat('width:', ancestor::table/colgroup/col[position() = preceding-sibling::td/@colspam +1]/@width, ';')"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:if test="@fill">
                        <xsl:value-of select="concat('background-color: ','#',@fill, ';')"/>
                    </xsl:if>
                    <xsl:if test="@align">
                        <xsl:value-of select="concat('text-align:',@align,';')"/>
                    </xsl:if>
                    <xsl:value-of select="concat('width:', ancestor::table/colgroup/col[position() = $pos]/@width, ';')"/>  
                </xsl:otherwise>
            </xsl:choose>
        </xsl:attribute>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Я пытаюсь взять предыдущее значение td colspan + 1 в качестве текущей позиции td, но оно генерирует пустое значение td.пожалуйста, предложите.

Answer 1

Вы можете определить переменную для получения фактической позиции td с учетом colspans, например,

<xsl:variable name="colpos" 
              select="sum(preceding-sibling::td/@colspan) + count(preceding-sibling::td[not(@colspan)]) + 1" />

Или, когда вы используете XSLT 2.0, вы можете написать выражение так...

<xsl:variable name="colpos" 
              select="sum(for $td in preceding-sibling::td return (if ($td/@colspan) then $td/@colspan else 1)) + 1" />

Или вот это ...

<xsl:variable name="colpos" 
              select="sum(preceding-sibling::td/(if (@colspan) then number(@colspan) else 1)) + 1" />

Итак, суммируйте colspans там, где они существуют, и сосчитайте те, без которых (которые имеют colspan 1).

Затем вам нужно получить количество столбцов в colgroup для суммирования, например так:

<xsl:variable name="colspan" 
              select="if (@colspan) then number(@colspan) else 1" />

Затем, чтобы получить ширину td, вы можете сделать это

 <xsl:value-of 
      select="concat('width:', 
                sum(ancestor::table/colgroup/col[position() ge $colpos and position() lt $colpos + $colspan]/number(replace(@width, '%', ''))), 
                '%;')"/>  

Попробуйте этот шаблон

<xsl:template match="td">
  <xsl:copy>
    <xsl:attribute name="style">
      <xsl:if test="@fill">
        <xsl:value-of select="concat('background-color: ','#',@fill, ';')"/>
      </xsl:if>
      <xsl:if test="@align">
        <xsl:value-of select="concat('text-align:',@align,';')"/>
      </xsl:if>
      <xsl:variable name="colpos" select="sum(preceding-sibling::td/@colspan) + count(preceding-sibling::td[not(@colspan)]) + 1" />
      <xsl:variable name="colspan" select="if (@colspan) then number(@colspan) else 1" />
      <xsl:value-of select="concat('width:', sum(ancestor::table/colgroup/col[position() ge $colpos and position() lt $colpos + $colspan]/number(replace(@width, '%', ''))), '%;')"/>  
    </xsl:attribute>
    <xsl:apply-templates/>
  </xsl:copy>
</xsl:template>