Как я могу использовать dlmopen в Фортране?

Question

Я хочу загрузить один и тот же файл .so дважды как отдельные экземпляры.На основе примера я создал приложение с двумя dlopen командами.

Однако я столкнулся с некоторыми проблемами и понял, что dlmopen должноиспользовать, если я использую несколько экземпляров одного и того же .so .Однако я не знаю, как передать аргументы.Может кто-нибудь помочь мне, как это сделать в GFortran?

Мой код, как показано ниже,

program example
    use :: iso_c_binding
implicit none

    integer(c_int), parameter :: rtld_lazy=1 ! value extracte from the C header file
    integer(c_int), parameter :: rtld_now=2 ! value extracte from the C header file
    !
    ! interface to linux API
    interface
        function dlopen(filename,mode) bind(c,name="dlopen")
            ! void *dlopen(const char *filename, int mode);
            use iso_c_binding
            implicit none
            type(c_ptr) :: dlopen
            character(c_char), intent(in) :: filename(*)
            integer(c_int), value :: mode
        end function

        function dlsym(handle,name) bind(c,name="dlsym")
            ! void *dlsym(void *handle, const char *name);
            use iso_c_binding
            implicit none
            type(c_funptr) :: dlsym
            type(c_ptr), value :: handle
            character(c_char), intent(in) :: name(*)
        end function

        function dlclose(handle) bind(c,name="dlclose")
            ! int dlclose(void *handle);
            use iso_c_binding
            implicit none
            integer(c_int) :: dlclose
            type(c_ptr), value :: handle
        end function
    end interface

    ! Define interface of call-back routine.
    abstract interface
        subroutine called_proc (i, i2) bind(c)
            use, intrinsic :: iso_c_binding
            integer(c_int), intent(in) :: i
            integer(c_int), intent(out) :: i2
        end subroutine called_proc
    end interface

    ! testing the dynamic loading
    integer i, i2
    type(c_funptr) :: proc_addr
    type(c_ptr) :: handle1, handle2
    character(256) :: pName, lName

    procedure(called_proc), bind(c), pointer :: proc
    !
    i = 15

    handle1=dlopen("./test.so"//c_null_char, RTLD_LAZY)
    if (.not. c_associated(handle1))then
        print*, 'Unable to load DLL ./test.so - First time'
        stop
    end if
    handle2=dlopen("./test.so"//c_null_char, RTLD_LAZY)
    if (.not. c_associated(handle2))then
        print*, 'Unable to load DLL ./test.so - Second time'
        stop
    end if

    ! If I can use dlmopen() I dont know how to pass the arguments

    proc_addr=dlsym(handle, "t_times2"//c_null_char)
    if (.not. c_associated(proc_addr))then
        write(*,*) 'Unable to load the procedure t_times2'
        stop
    end if
    call c_f_procpointer( proc_addr, proc )
    call proc(i,i2)
    write(*,*) "t_times2, i2=", i2
    !
    proc_addr=dlsym( handle, "t_square"//c_null_char )
    if ( .not. c_associated(proc_addr) )then
        write(*,*)'Unable to load the procedure t_square'
        stop
    end if
    call c_f_procpointer(proc_addr, proc)
    call proc(i,i2)
    write(*,*) "t_square, i2=", i2
contains
end program example

Обновление: Основываясь на предложении от Владмира, я попробовал нижено я получаю Unable to load DLL ./test.so - Third time,

        function dlmopen(lmid_t,filename,mode) bind(c,name="dlmopen")
            ! void *dlopen(const char *filename, int mode);
            use iso_c_binding
            implicit none
            type(c_ptr) :: dlopen
            integer(c_long), value :: lmid_t
            character(c_char), intent(in) :: filename(*)
            integer(c_int), value :: mode
        end function


    handle3=dlmopen(1,"./test.so"//c_null_char, RTLD_LAZY)
    if (.not. c_associated(handle3))then
        print*, 'Unable to load DLL ./test.so - Third time'
        stop
    end if

Answer 1

Это база, с которой вы можете начать, это модификация вашего кода, и из-за макросов #define она требует флагов cpp.Вы можете изменить определения на обычное объявление параметров, если хотите, но проще просто скопировать макросы из заголовка.

    use iso_c_binding

    implicit none

! from dlfcn.h
# define LM_ID_BASE 0   /* Initial namespace.  */
# define LM_ID_NEWLM    -1  /* For dlmopen: request new namespace.  */

    integer(c_long) :: dlist = LM_ID_NEWLM
    integer(c_int), parameter :: rtld_lazy=1 ! value extracte from the C header file
    integer(c_int), parameter :: rtld_now=2 ! value extracte from the C header file
    type(c_ptr) :: handle3     

    interface
        function dlmopen(lmid_t,filename,mode) bind(c,name="dlmopen")
            ! void *dlmopen (Lmid_t lmid, const char *filename, int flags);
            use iso_c_binding
            implicit none
            type(c_ptr) :: dlmopen
            integer(c_long), value :: lmid_t
            character(c_char), intent(in) :: filename(*)
            integer(c_int), value :: mode
        end function
    end interface

    handle3=dlmopen(dlist,"test.so"//c_null_char, RTLD_LAZY)
    if (.not. c_associated(handle3))then
        print*, 'Unable to load DLL ./test.so - Third time'
        stop
    end if
end    

Согласно руководству, есть два основных значения, которые вы можете передать как dlist, либо LM_ID_BASE, либо LM_ID_NEWLM.Их значения определены в заголовке dlfcn.h, который находится среди других стандартных заголовков C и POSIX (/usr/include/ или аналогичных).Вы должны не просто передать 1, но одно из этих двух значений, которые на моем компьютере равны 0 и -1.