Delphi удаляет символы из строки - PullRequest
Новая
       70

Delphi удаляет символы из строки

0 голосов
/ 06 февраля 2019

Я искал и пробовал несколько циклов, которые должны удалять символы из строки, мне это нужно, потому что в определенных местах может быть символ "/" или другой тип символа, и мне нужно его удалить, так как FTP будет думать, что этопапка, и мне нужна строка в имени.

Строка «место» зависит от текущего рабочего места человека, например, есть «место» = «S / A StorageRoom», часть «/»FTP для String make считает, что это подпапка.

Пока я использую это, я думаю, оно довольно большое и может использовать «сокращение»: 

   place := StringReplace(place, ',', '', [rfReplaceAll]);
   place := StringReplace(place, '.', '', [rfReplaceAll]);
   place := StringReplace(place, '/', '', [rfReplaceAll]);
   place := StringReplace(place, '!', '', [rfReplaceAll]);
   place := StringReplace(place, '@', '', [rfReplaceAll]);
   place := StringReplace(place, '#', '', [rfReplaceAll]);
   place := StringReplace(place, '$', '', [rfReplaceAll]);
   place := StringReplace(place, '%', '', [rfReplaceAll]);
   place := StringReplace(place, '^', '', [rfReplaceAll]);
   place := StringReplace(place, '&', '', [rfReplaceAll]);
   place := StringReplace(place, '*', '', [rfReplaceAll]);
   place := StringReplace(place, '''', '', [rfReplaceAll]);
   place := StringReplace(place, '"', '', [rfReplaceAll]);
   place := StringReplace(place, ';', '', [rfReplaceAll]);
   place := StringReplace(place, '_', '', [rfReplaceAll]);
   place := StringReplace(place, '(', '', [rfReplaceAll]);
   place := StringReplace(place, ')', '', [rfReplaceAll]);
   place := StringReplace(place, ':', '', [rfReplaceAll]);
   place := StringReplace(place, '|', '', [rfReplaceAll]);
   place := StringReplace(place, '[', '', [rfReplaceAll]);
   place := StringReplace(place, ']', '', [rfReplaceAll]);
   place := StringReplace(place, '\', '', [rfReplaceAll]);

Редактировать: Iв настоящее время использую RAD Studio 10.1 Berlin

Ответы [ 2 ]

0 голосов
/ 06 февраля 2019

В стремлении избежать ненужных выделений кучи, вот вариант ответа @ Ancaron, который только делает одно выделение и окончательное уменьшение размера для получения ответа.

Хитрость заключается в том, чтобы предварительно выделить результирующееСтрока в начале, а затем заполните ее принятыми символами.В конце скорректируйте полученную длину строки. 

program TestStripChars;

{$APPTYPE CONSOLE}

uses
  SysUtils;

function StripChars (const Text : string; const InValidChars : SysUtils.TSysCharSet) : string;
var
  i,j : Integer;
begin
  SetLength(Result,Length(Text));  // Preallocate result maximum length
  j := 0;  // Resulting string length counter
  for i := 1 to Length(Text) do begin
    if not CharInSet(Text[i],InValidChars) then begin
      Inc(j);
      Result[j] := Text[i];
    end;
  end;
  SetLength(Result,j); // Set result actual length
end;

var
  place : String;
begin
  place := 'Hell$$o D.,e.$lphi';
  place := StripChars(place,[',','.','$']);
  WriteLn(place);
  ReadLn;
end.

Из комментария видно, что OP использует настройку компилятора с обработкой строки на основе нуля.

Вотфункция, которая обрабатывает оба сценария: 

function StripChars ( const Text : string; const InValidChars : SysUtils.TSysCharSet) : string;
var
  i,j,zbsAdj : Integer;
begin
  SetLength(Result,Length(Text));  // Preallocate result maximum length
  j := 0; // Resulting string length counter
  zbsAdj := 1-Low(String); // Handles zero based string offset
  for i := Low(Text) to High(Text) do begin
    if not CharInSet(Text[i],InValidChars) then begin
      Inc(j);
      Result[j-zbsAdj] := Text[i];
    end;
  end;
  SetLength(Result,j); // Set result actual length
end;
0 голосов
/ 06 февраля 2019

Вы просто используете функцию типа 

function StripChars ( const Text : string; InValidChars : TSetOfChar ) : string;
var
  S : string;
  i : integer;
begin
  Result := '';
  if Length(Text) > 0 then
  begin
    S := '';
    for i := 1 to length ( Text ) do
      if not CharInSet(Text[i],InValidChars) then  
        S := S + Text [ i ];
    Result := S;
  end;
end;

, а затем только вызываете 

place := StripChars(place,[',','.', and so on]);
...