Как распределить процент производства по нескольким рабочим центрам?

Question

Я не могу найти правильную формулу для распределения процента производства, когда продукт проходит через несколько рабочих центров.

У меня есть производство моей компании по весу, по процентам и по рабочим центрам, поэтому я могу добавитьвсе проценты, которые принадлежат конкретному рабочему центру.

Производство по рабочему центру:

Я использую формулу:

=sumif(column_of_workcenters,work_center,column_of_percentages)

С ссылками на ячейки это выглядит примерно так:

=SUMAR.SI($H$44:$H$50,"*"&J44&"*",$G$44:$G$50)

Формула для суммы:

Я попробовал несколько комбинаций формул количества и суммы без удачи.Я думаю, что проблема заключается в подходе «сумма, если содержит рабочий центр».

Если продукту назначено несколько рабочих мест, они все добавляют, а не распределяют одинаково.

Текущие значения:

Это должно быть примерно так:

Ожидаемые значения:

Любыепомощь приветствуется.

Answer 1

Вы можете попробовать это.Введите

=SUMPRODUCT($G$44:$G$50,IF(IFERROR(FIND(J44,$H$44:$H$50,1),0)>0,1,0),2/(LEN($H$44:$H$50)+1))

в ячейку K44 в качестве формулы массива (CTRL-SHIFT-ENTER), затем скопируйте в K45 и K46.

Пояснение

Для каждого из a,b,c формула использует SUMPRODUCT для вычисления:

SUM(PERCENT_IN_COLUMN_G × NUMERATOR ÷ DENOMINATOR)

NUMERATOR равен 1, если, скажем, a находится в столбце H и 0, если неттам.В формуле это обрабатывается как

IF(IFERROR(FIND(J44,$H$44:$H$50,1),0)>0,1,0)

DENOMINATOR - это количество букв в столбце H. Предполагая, что каждая запись в столбце H является разделенным запятыми списком букв, мы можем получить количество букв с помощью

(LEN($H$44:$H$50)+1)/2

Поскольку мы хотим поделить на это значение, мы используем его обратное значение в формуле

2/(LEN($H$44:$H$50)+1) 

Так что эта формула все равно будет работать, если у вас есть a,b,c,d или что-то еще в столбце H.

Надеюсь, это поможет.

Answer 2

Если вы можете использовать вспомогательный столбец, вставьте следующую формулу в I44:

=G44/(LEN(H44)-LEN(SUBSTITUTE(H44,",",""))+1)

и заполните.

Затем в K44 используйте:

=SUMIF(H44:H50,"*"&J44&"*",I44:I50)

И снова заселение (для каждого рабочего центра)